Programování zvukových karet s čipem OPL 3: modifikace tvaru vlny a zvukové kanály se čtyřmi operátory

Obsah

1. Programování zvukových karet s čipem OPL 3: modifikace tvaru vlny a zvukové kanály se čtyřmi operátory

2. Tvary vln, které lze využít v čipech OPL2

3. Tvary vln, které lze využít v čipech OPL3

4. Interaktivní modifikace tvaru vlny u prvního operátoru

5. Úplný zdrojový kód dnešního prvního demonstračního příkladu

6. Oprava chyby: povolení režimu kompatibilního s OPL3

7. Úplný zdrojový kód dnešního druhého demonstračního příkladu

8. Vliv změny tvaru vlny na zvuk s FM syntézou

9. Úplný zdrojový kód dnešního třetího demonstračního příkladu

10. Modifikace tvaru nosné vlny i modulátoru

11. Úplný zdrojový kód dnešního čtvrtého demonstračního příkladu

12. Režim, ve kterém je jeden kanál tvořen čtyřmi operátory

13. Realizace spojení kanálů tak, aby byly k dispozici čtyři operátory

14. Způsoby vzájemného propojení čtyř operátorů (algoritmy)

15. Interaktivní přepínání AM a FM režimů u kanálu se čtyřmi operátory

16. Úplný zdrojový kód dnešního pátého demonstračního příkladu

17. Změna parametrů obálky v režimu se čtyřmi operátory

18. Příloha: skript pro vykreslení sedmi signálů generovaných oscilátory čipu OPL3

19. Repositář s demonstračními příklady

20. Odkazy na Internetu

1. Programování zvukových karet s čipem OPL 3: modifikace tvaru vlny a zvukové kanály se čtyřmi operátory

Již popáté se v seriálu o tvorbě her a grafických dem na platformě IBM PC vracíme k tématu programování zvukových karet, které obsahují čipy OPL2, dvojici čipů OPL2 nebo novější čip OPL3. Základy tvorby hudby s využitím OPL2 byly popsány v článcích Zvuky a hudba na platformě IBM PC: čip OPL2 aneb Yamaha YM3812 a Zvuky a hudba na platformě IBM PC: složitější zvuky s OPL2, dalšímu vývoji zvukových karet od OPL2 směrem k OPL3 jsme se věnovali v článku Vývoj zvukových karet pro platformu IBM PC po vydání karty AdLib a minule jsme si ukázali, jakým způsobem je možné využít dvě nové vlastnosti OPL3: možnost tvorby stereo zvuku a taktéž využití osmnácti zvukových kanálů s celkem 36 operátory.

Dnes si ukážeme další možnosti OPL3. V první řadě je vhodné prozkoumat, jaké nové tvary vln (waveform) jsou dostupné a nesmíme zapomenout ještě na mnohem zásadnější změnu – na možnost spojit některé zvukové kanály takovým způsobem, aby se zde využily čtyři operátory a nikoli pouze operátory dva. To, společně s výběrem AM či FM (resp. PM) syntézy a taktéž s možností nastavení zpětné vazby značným způsobem rozšiřuje možnosti čipů OPL3 (které navíc nebyly poměrně dlouho dobře využívány), i když v oblasti profesionální hudby se používá ještě větší počet operátorů. Například slavné klávesy Yamaha DX7 nabízely šest operátorů a celkem 32 jejich kombinací (zde nazývaných „algoritmy“). K tomu se ovšem ještě vrátíme později v článcích o MIDI.

2. Tvary vln, které lze využít v čipech OPL2

Nejprve se na chvíli vraťme k čipům OPL2, které jsou interně jednodušší a tím pádem i snadnější na pochopení. V těchto čipech mohl každý oscilátor (v OPL2 jich bylo celkem osmnáct) generovat periodický signál odvozený od klasické sinusovky. Podoba této sinusovky je uložena v ROM přímo na hudebním čipu. Přesněji řečeno je zde uložena jen jedna čtvrtina sinusovky, protože zbylé části lze snadno dopočítat zrcadlením okolo x-ové nebo y-ové osy (navíc jsou hodnoty uloženy zlogaritmované, aby se snadněji násobily, to je však interní vlastnost OPL2, s níž se přímo nesetkáme). Všechny čtyři varianty signálu podporované OPL2 jsou zobrazeny na dalším obrázku:

Obrázek 1: Sinusová vlna.

Obrázek 2: Jen kladné půlvlny.

Tvary vlny bylo možné volit nastavením spodních dvou bitů registrů E0 až F5 (tedy skutečně pro každý operátor – nikoli pouze pro kanál).

Obrázek 3: Absolutní hodnota sinusovky.

Obrázek 4: Jen náběžné hrany sinusovky.

3. Tvary vln, které lze využít v čipech OPL3

V čipech OPL3 se k původním čtyřem volitelným tvarům vln přidaly ještě další čtyři tvary. Jedná se v první řadě o sinusovku upravenou takovým způsobem, že nenulové jsou jen vlny ze sudých period a dále o absolutní hodnoty tohoto průběhu:

Obrázek 5: Pouze sudé periody sinusovky.

Obrázek 6: Absolutní hodnota předešlého signálu.

Další dva tvary vln jsou zcela odlišné, protože se jedná o obdélníkový signál (tak oblíbený ve starších čipech z éry osmibitových domácích mikropočítačů a herních konzolí) a taktéž o signál, který zhruba odpovídá derivaci obdélníkového signálu – záporný impuls následovaný kladným impulsem (na rozdíl od skutečné derivace samozřejmě nejde o Diracovy impulsy).

<

Obrázek 7: Obdélníkový průběh.

Samotný signál s derivací obdélníkového signálu ve skutečnosti vypadá následovně.

Tvary vln, tedy opět výběr jednoho z osmi dostupných tvarů, se stále provádí přes registry E0 až F5, kde nyní mají význam spodní tři bity a nejenom bity dva.

4. Interaktivní modifikace tvaru vlny u prvního operátoru

Vyzkoušejme si, jakým způsobem je možné modifikovat tvar vlny generované oscilátorem, jenž je připojený na první operátor prvního kanálu. Nejprve nastavíme AM syntézu, takže se výsledný signál produkovaný prvním operátorem přímo pošle na D/A převodník a nebude se jednat o „pouhý“ modulátor pro FM syntézu. Do tabulky s nastavením OPL2/OPL3 tedy zapíšeme tento řádek:

db CHANNEL_1 + OPL_FEEDBACK,                   0b00110001  ; volba AM-FM

Dále nastavíme obálku pro operátor:

db CHANNEL_1_OPERATOR_1 + OPL_AMP_VIBRATO_EG,  0x01  ; nastaveni modulatoru: nasobeni frekvence jednickou
db CHANNEL_1_OPERATOR_1 + OPL_LEVEL,           0x00  ; uroven vystupu 40 dB
db CHANNEL_1_OPERATOR_1 + OPL_ATTACK_DECAY,    0xf0  ; modulator: pomaly nastup zvuku + pomale doznivani
db CHANNEL_1_OPERATOR_1 + OPL_SUSTAIN_RELEASE, 0x77  ; urovne sustain a release pro modulator

Zvolíme základní tvar vlny:

db CHANNEL_1_OPERATOR_1 + OPL_WAVE_SELECT,     0x00  ; standardni sinus

A nastavíme frekvenci pro celý kanál:

db CHANNEL_1 + OPL_FREQUENCY_LOW,              0x41  ; frekvence zvuku (komorni A = 440 Hz)
db CHANNEL_1 + OPL_KEY_ON,                     0x12  ; zapnuti/povoleni zvuku + nastaveni oktavy a vyssich bitu frekvence

Samotné přepínání tvaru vlny bude provedeno klávesami 1–8 (1 je sinus, 7 je obdélník atd.) a mezerníkem se tón přehraje – nastaví se bit KEY ON tak, jak to již dobře známe:

.opak:
        in  al, PPI_PORT_A               ; cteni stisknute klavesy
        cmp al, KEY_SPACE                ; test na stisk mezerniku
        jne .next_test_1                 ; neni stisknut -> preskok
        write_opl_register CHANNEL_1 + OPL_KEY_ON, 0x32    ; povoleni KEY ON bitu
        jmp .opak
.next_test_1:
        cmp al, KEY_SPACE + KEY_RELEASE  ; test na pusteni mezerniku
        jne .next_test_2                 ; neni pusten -> dalsi test
        write_opl_register CHANNEL_1 + OPL_KEY_ON, 0x12    ; zakaz KEY ON bitu
        jmp .opak
.next_test_2:
        cmp al, KEY_1                    ; test na numericke klavesy
        jb  .next_test_3                 ; hodnota "pod" kodem klavesy 1
        cmp al, KEY_8
        ja  .next_test_3                 ; hodnota "nad" kodem klavesy 8
        mov bl, al                       ; makro prepisuje AL -> nemuzeme ho primo pouzit
        sub bl, KEY_1
        write_opl_register CHANNEL_1_OPERATOR_1 + OPL_WAVE_SELECT, bl
        jmp .opak
.next_test_3:

5. Úplný zdrojový kód dnešního prvního demonstračního příkladu

Úplný zdrojový kód demonstračního příkladu umožňujícího interaktivní změnu tvaru vlny pomocí kláves 1–8 vypadá následovně:

; Prehrani zakladniho tonu na kartach s cipem OPL3.
; Prepinani tvaru vlny pro generovani zvuku.
; Pojmenovani registru OPL3.
; Ovladani KEY ON mezernikem
; Tvar vlny je rizen klavesami 1 az 8
; Ukonceni aplikace stiskem ESC
;
;
; Tento demonstracni priklad je pouzity v serialu o programovani
; grafickych dem a her na PC v DOSu:
; https://www.root.cz/serialy/vyvoj-her-a-grafickych-dem-pro-platformu-pc/
;
;
; preklad pomoci:
;     nasm -f bin -o sounds_opl3_waveform_1.com sounds_opl3_waveform_1.asm
;
; nebo pouze:
;     nasm -o sounds_opl3_waveform_1.com sounds_opl3_waveform_1.asm
 
;-----------------------------------------------------------------------------
 
BITS 16         ; 16bitovy vystup pro DOS
CPU 8086        ; specifikace pouziteho instrukcniho souboru
 
 
;-----------------------------------------------------------------------------
 
; registry karet s cipem OPL2 nebo OPL3
OPL_ADDRESS           equ 0x220
OPL_DATA              equ 0x221
 
; ridici registry OPL2
OPL_TEST_LSI          equ 0x01
OPL_TIMER_1           equ 0x02
OPL_TIMER_2           equ 0x03
OPL_TIMER_CTRL        equ 0x04
OPL_KBSPLIT           equ 0x08
OPL_AMP_VIBRATO_EG    equ 0x20
OPL_LEVEL             equ 0x40
OPL_ATTACK_DECAY      equ 0x60
OPL_SUSTAIN_RELEASE   equ 0x80
OPL_FREQUENCY_LOW     equ 0xa0
OPL_KEY_ON            equ 0xb0
OPL_AM_VIBRATO_RHYTHM equ 0xbd
OPL_FEEDBACK          equ 0xc0
OPL_WAVE_SELECT       equ 0xe0
OPL3_MODE_ENABLE      equ 0x05  ; vyssi port!!!
 
; indexy kanalu
CHANNEL_1 equ 0
CHANNEL_2 equ 1
CHANNEL_3 equ 2
CHANNEL_4 equ 3
CHANNEL_5 equ 4
CHANNEL_6 equ 5
CHANNEL_7 equ 6
CHANNEL_8 equ 7
CHANNEL_9 equ 8
 
; offsety pro jednotlive operatory
; --------------------------------------------------
;  Channel        1   2   3   4   5   6   7   8   9
;  Operator 1    00  01  02  08  09  0A  10  11  12
;  Operator 2    03  04  05  0B  0C  0D  13  14  15
; --------------------------------------------------
;  Channel        1   2   3   4   5   6   7   8   9
CHANNEL_1_OPERATOR_1 equ 0x00
CHANNEL_1_OPERATOR_2 equ 0x03
CHANNEL_2_OPERATOR_1 equ 0x01
CHANNEL_2_OPERATOR_2 equ 0x04
CHANNEL_3_OPERATOR_1 equ 0x02
CHANNEL_3_OPERATOR_2 equ 0x05
CHANNEL_4_OPERATOR_1 equ 0x08
CHANNEL_4_OPERATOR_2 equ 0x0b
CHANNEL_5_OPERATOR_1 equ 0x09
CHANNEL_5_OPERATOR_2 equ 0x0c
CHANNEL_6_OPERATOR_1 equ 0x0a
CHANNEL_6_OPERATOR_2 equ 0x0d
CHANNEL_7_OPERATOR_1 equ 0x10
CHANNEL_7_OPERATOR_2 equ 0x13
CHANNEL_8_OPERATOR_1 equ 0x11
CHANNEL_8_OPERATOR_2 equ 0x14
CHANNEL_9_OPERATOR_1 equ 0x12
CHANNEL_9_OPERATOR_2 equ 0x15
 
; registry PPI
PPI_PORT_A equ 0x60
PPI_PORT_B equ 0x61
 
; kody klaves
KEY_ESC     equ 0x01
KEY_SPACE   equ 0x39
KEY_RELEASE equ 0x80
KEY_1       equ 0x02
KEY_8       equ KEY_1 + 8
 
 
;-----------------------------------------------------------------------------
 
; ukonceni procesu a navrat do DOSu
%macro exit 0
        ret
%endmacro
 
; makro pro zapis do registru OPL2
%macro write_opl_register 2
        mov     al, %1
        mov     ah, %2
        call    perform_write_to_opl_register
%endmacro
 
;-----------------------------------------------------------------------------
org  0x100        ; zacatek kodu pro programy typu COM (vzdy se zacina na 256)
 
start:
        push cs
        pop  ds                          ; DS==CS
 
        mov  si, tone1                   ; zacatek tabulky
        call write_table_to_opl2         ; zapis obsahu tabulky do OPL2
 
        in  al, PPI_PORT_B               ; port B s rizenim zarizeni
        or  al, 0b1000000                ; nastaveni bitu cislo 7 na jednicku
        out PPI_PORT_B, al               ; zapis zpet na port B
 
.opak:
        in  al, PPI_PORT_A               ; cteni stisknute klavesy
        cmp al, KEY_SPACE                ; test na stisk mezerniku
        jne .next_test_1                 ; neni stisknut -> preskok
        write_opl_register CHANNEL_1 + OPL_KEY_ON, 0x32    ; povoleni KEY ON bitu
        jmp .opak
.next_test_1:
        cmp al, KEY_SPACE + KEY_RELEASE  ; test na pusteni mezerniku
        jne .next_test_2                 ; neni pusten -> dalsi test
        write_opl_register CHANNEL_1 + OPL_KEY_ON, 0x12    ; zakaz KEY ON bitu
        jmp .opak
.next_test_2:
        cmp al, KEY_1                    ; test na numericke klavesy
        jb  .next_test_3                 ; hodnota "pod" kodem klavesy 1
        cmp al, KEY_8
        ja  .next_test_3                 ; hodnota "nad" kodem klavesy 8
        mov bl, al                       ; makro prepisuje AL -> nemuzeme ho primo pouzit
        sub bl, KEY_1
        write_opl_register CHANNEL_1_OPERATOR_1 + OPL_WAVE_SELECT, bl
        jmp .opak
.next_test_3:
        cmp al, KEY_ESC                  ; test stisknute klavesy ESC
        jne .opak                        ; neni stisknuta? -> zkusme znovu
 
        exit
 
write_table_to_opl2:
        lodsb                            ; nacist bajt z tabulky (cislo registru)
        or  al, al                       ; test na nulu
        jnz .write_register
        ret                              ; dosahli jsme konce tabulky
.write_register:
        mov ah, al
        lodsb                            ; nacist dalsi bajt z tabulky (hodnota registru)
        xchg al, ah                      ; podprogram vyzaduje opacne poradi AL, AH
        call perform_write_to_opl_register
        jmp  write_table_to_opl2         ; muzeme prejit na dalsi registr
 
 
tone1:  ; tabulka s tonem pro prvni kanal
        db CHANNEL_1_OPERATOR_1 + OPL_AMP_VIBRATO_EG,  0x01  ; nastaveni modulatoru: nasobeni frekvence jednickou
        db CHANNEL_1_OPERATOR_1 + OPL_LEVEL,           0x00  ; uroven vystupu 40 dB
        db CHANNEL_1_OPERATOR_1 + OPL_ATTACK_DECAY,    0xf0  ; modulator: pomaly nastup zvuku + pomale doznivani
        db CHANNEL_1_OPERATOR_1 + OPL_SUSTAIN_RELEASE, 0x77  ; urovne sustain a release pro modulator
        db CHANNEL_1_OPERATOR_2 + OPL_AMP_VIBRATO_EG,  0x01  ; nastaveni nosne: nasobeni frekvence jednickou
        db CHANNEL_1_OPERATOR_2 + OPL_LEVEL,           0x00  ; nastaveni urovne vystupu nosne na 47 dB
        db CHANNEL_1_OPERATOR_2 + OPL_ATTACK_DECAY,    0xf0  ; nosna: rychly nastup + pomale doznivani
        db CHANNEL_1_OPERATOR_2 + OPL_SUSTAIN_RELEASE, 0x77  ; urovne sustain a release pro nosnou
        db CHANNEL_1_OPERATOR_1 + OPL_WAVE_SELECT,     0x00  ; standardni sinus
        db CHANNEL_1 + OPL_FREQUENCY_LOW,              0x41  ; frekvence zvuku (komorni A = 440 Hz)
        db CHANNEL_1 + OPL_KEY_ON,                     0x12  ; zapnuti/povoleni zvuku + nastaveni oktavy a vyssich bitu frekvence
        db CHANNEL_1 + OPL_FEEDBACK,                   0b00110001  ; volba AM-FM
        db 0, 0                                              ; zarazka
 
 
 
perform_write_to_opl_register:
        ; zapis do vybraneho registru OPL2
        ; AL - registr
        ; AH - hodnota
        mov dx, OPL_ADDRESS   ; vyber registru pro modifikaci
        out dx, al
 
        mov al, ah            ; zapis hodnoty do vybraneho registru
        mov dx, OPL_DATA
        out dx, al
 
        ret

6. Oprava chyby: povolení režimu kompatibilního s OPL3

V případě, že jste si předchozí demonstrační příklad skutečně přeložili a vyzkoušeli, pravděpodobně jste zjistili, že tóny po stisku kláves 1 a 5 jsou totožné. Totéž platí pro klávesy 2 a 6 atd. Je tomu tak z toho důvodu, že po resetu je čip OPL3 nastaven do režimu zpětné kompatibility s čipem OPL2, což omezuje jak nastavení sterea (což jsme viděli minule), tak i možnost využití třetího bitu v registrech E0 až F5 – význam tudíž mají jen nejnižší dva bity. Aby bylo možné vybrat i další čtyři tvary vln, je nutné se přepnout do režimu kompatibilního s OPL3:

        write_opl_high_register OPL3_MODE_ENABLE, 1

Pro tento účel slouží následující makro:

; makro pro zapis do "vyssiho" registru OPL3
%macro write_opl_high_register 2
        mov     al, %1
        mov     ah, %2
        call    perform_write_to_opl_high_register
%endmacro

To využívá subrutinu pro zápis do vybraného vyššího registru OPL3:

perform_write_to_opl_high_register:
        ; zapis do vybraneho "vyssiho" registru OPL3
        ; AL - registr
        ; AH - hodnota
        mov dx, OPL_HIGH_ADDRESS   ; vyber registru pro modifikaci
        out dx, al
 
        mov al, ah                 ; zapis hodnoty do vybraneho registru
        mov dx, OPL_HIGH_DATA
        out dx, al
 
        ret

7. Úplný zdrojový kód dnešního druhého demonstračního příkladu

Opravená varianta demonstračního příkladu, který nyní umožní skutečně vybrat jednu z osmi dostupných tvarů vln, vypadá následovně:

; Prehrani zakladniho tonu na kartach s cipem OPL3.
; Prepnuti do rezimu OPL3.
; Prepinani tvaru vlny pro generovani zvuku.
; Pojmenovani registru OPL3.
; Ovladani KEY ON mezernikem
; Tvar vlny je rizen klavesami 1 az 8
; Ukonceni aplikace stiskem ESC
;
;
; Tento demonstracni priklad je pouzity v serialu o programovani
; grafickych dem a her na PC v DOSu:
; https://www.root.cz/serialy/vyvoj-her-a-grafickych-dem-pro-platformu-pc/
;
;
; preklad pomoci:
;     nasm -f bin -o sounds_opl3_waveform_2.com sounds_opl3_waveform_2.asm
;
; nebo pouze:
;     nasm -o sounds_opl3_waveform_2.com sounds_opl3_waveform_2.asm
 
;-----------------------------------------------------------------------------
 
BITS 16         ; 16bitovy vystup pro DOS
CPU 8086        ; specifikace pouziteho instrukcniho souboru
 
 
;-----------------------------------------------------------------------------
 
; registry karet s cipem OPL3
OPL_ADDRESS           equ 0x220
OPL_DATA              equ 0x221
OPL_HIGH_ADDRESS      equ 0x222
OPL_HIGH_DATA         equ 0x223
 
; ridici registry OPL2
OPL_TEST_LSI          equ 0x01
OPL_TIMER_1           equ 0x02
OPL_TIMER_2           equ 0x03
OPL_TIMER_CTRL        equ 0x04
OPL_KBSPLIT           equ 0x08
OPL_AMP_VIBRATO_EG    equ 0x20
OPL_LEVEL             equ 0x40
OPL_ATTACK_DECAY      equ 0x60
OPL_SUSTAIN_RELEASE   equ 0x80
OPL_FREQUENCY_LOW     equ 0xa0
OPL_KEY_ON            equ 0xb0
OPL_AM_VIBRATO_RHYTHM equ 0xbd
OPL_FEEDBACK          equ 0xc0
OPL_WAVE_SELECT       equ 0xe0
OPL3_MODE_ENABLE      equ 0x05  ; vyssi port!!!
 
; indexy kanalu
CHANNEL_1 equ 0
CHANNEL_2 equ 1
CHANNEL_3 equ 2
CHANNEL_4 equ 3
CHANNEL_5 equ 4
CHANNEL_6 equ 5
CHANNEL_7 equ 6
CHANNEL_8 equ 7
CHANNEL_9 equ 8
 
; offsety pro jednotlive operatory
; --------------------------------------------------
;  Channel        1   2   3   4   5   6   7   8   9
;  Operator 1    00  01  02  08  09  0A  10  11  12
;  Operator 2    03  04  05  0B  0C  0D  13  14  15
; --------------------------------------------------
;  Channel        1   2   3   4   5   6   7   8   9
CHANNEL_1_OPERATOR_1 equ 0x00
CHANNEL_1_OPERATOR_2 equ 0x03
CHANNEL_2_OPERATOR_1 equ 0x01
CHANNEL_2_OPERATOR_2 equ 0x04
CHANNEL_3_OPERATOR_1 equ 0x02
CHANNEL_3_OPERATOR_2 equ 0x05
CHANNEL_4_OPERATOR_1 equ 0x08
CHANNEL_4_OPERATOR_2 equ 0x0b
CHANNEL_5_OPERATOR_1 equ 0x09
CHANNEL_5_OPERATOR_2 equ 0x0c
CHANNEL_6_OPERATOR_1 equ 0x0a
CHANNEL_6_OPERATOR_2 equ 0x0d
CHANNEL_7_OPERATOR_1 equ 0x10
CHANNEL_7_OPERATOR_2 equ 0x13
CHANNEL_8_OPERATOR_1 equ 0x11
CHANNEL_8_OPERATOR_2 equ 0x14
CHANNEL_9_OPERATOR_1 equ 0x12
CHANNEL_9_OPERATOR_2 equ 0x15
 
; registry PPI
PPI_PORT_A equ 0x60
PPI_PORT_B equ 0x61
 
; kody klaves
KEY_ESC     equ 0x01
KEY_SPACE   equ 0x39
KEY_RELEASE equ 0x80
KEY_1       equ 0x02
KEY_8       equ KEY_1 + 8
 
 
;-----------------------------------------------------------------------------
 
; ukonceni procesu a navrat do DOSu
%macro exit 0
        ret
%endmacro
 
; makro pro zapis do registru OPL2 nebo OPL3
%macro write_opl_register 2
        mov     al, %1
        mov     ah, %2
        call    perform_write_to_opl_register
%endmacro
 
; makro pro zapis do "vyssiho" registru OPL3
%macro write_opl_high_register 2
        mov     al, %1
        mov     ah, %2
        call    perform_write_to_opl_high_register
%endmacro
 
;-----------------------------------------------------------------------------
org  0x100        ; zacatek kodu pro programy typu COM (vzdy se zacina na 256)
 
start:
        push cs
        pop  ds                          ; DS==CS
 
        write_opl_high_register OPL3_MODE_ENABLE, 1
 
        mov  si, tone1                   ; zacatek tabulky
        call write_table_to_opl3         ; zapis obsahu tabulky do OPL3
 
        in  al, PPI_PORT_B               ; port B s rizenim zarizeni
        or  al, 0b1000000                ; nastaveni bitu cislo 7 na jednicku
        out PPI_PORT_B, al               ; zapis zpet na port B
 
.opak:
        in  al, PPI_PORT_A               ; cteni stisknute klavesy
        cmp al, KEY_SPACE                ; test na stisk mezerniku
        jne .next_test_1                 ; neni stisknut -> preskok
        write_opl_register CHANNEL_1 + OPL_KEY_ON, 0x32    ; povoleni KEY ON bitu
        jmp .opak
.next_test_1:
        cmp al, KEY_SPACE + KEY_RELEASE  ; test na pusteni mezerniku
        jne .next_test_2                 ; neni pusten -> dalsi test
        write_opl_register CHANNEL_1 + OPL_KEY_ON, 0x12    ; zakaz KEY ON bitu
        jmp .opak
.next_test_2:
        cmp al, KEY_1                    ; test na numericke klavesy
        jb  .next_test_3                 ; hodnota "pod" kodem klavesy 1
        cmp al, KEY_8
        ja  .next_test_3                 ; hodnota "nad" kodem klavesy 8
        mov bl, al                       ; makro prepisuje AL -> nemuzeme ho primo pouzit
        sub bl, KEY_1
        write_opl_register CHANNEL_1_OPERATOR_1 + OPL_WAVE_SELECT, bl
        jmp .opak
.next_test_3:
        cmp al, KEY_ESC                  ; test stisknute klavesy ESC
        jne .opak                        ; neni stisknuta? -> zkusme znovu
 
        exit
 
write_table_to_opl3:
        lodsb                            ; nacist bajt z tabulky (cislo registru)
        or  al, al                       ; test na nulu
        jnz .write_register
        ret                              ; dosahli jsme konce tabulky
.write_register:
        mov ah, al
        lodsb                            ; nacist dalsi bajt z tabulky (hodnota registru)
        xchg al, ah                      ; podprogram vyzaduje opacne poradi AL, AH
        call perform_write_to_opl_register
        jmp  write_table_to_opl3         ; muzeme prejit na dalsi registr
 
 
tone1:  ; tabulka s tonem pro prvni kanal
        db CHANNEL_1_OPERATOR_1 + OPL_AMP_VIBRATO_EG,  0x01  ; nastaveni modulatoru: nasobeni frekvence jednickou
        db CHANNEL_1_OPERATOR_1 + OPL_LEVEL,           0x00  ; uroven vystupu 40 dB
        db CHANNEL_1_OPERATOR_1 + OPL_ATTACK_DECAY,    0xf0  ; modulator: pomaly nastup zvuku + pomale doznivani
        db CHANNEL_1_OPERATOR_1 + OPL_SUSTAIN_RELEASE, 0x77  ; urovne sustain a release pro modulator
        db CHANNEL_1_OPERATOR_2 + OPL_AMP_VIBRATO_EG,  0x01  ; nastaveni nosne: nasobeni frekvence jednickou
        db CHANNEL_1_OPERATOR_2 + OPL_LEVEL,           0x00  ; nastaveni urovne vystupu nosne na 47 dB
        db CHANNEL_1_OPERATOR_2 + OPL_ATTACK_DECAY,    0xf0  ; nosna: rychly nastup + pomale doznivani
        db CHANNEL_1_OPERATOR_2 + OPL_SUSTAIN_RELEASE, 0x77  ; urovne sustain a release pro nosnou
        db CHANNEL_1_OPERATOR_1 + OPL_WAVE_SELECT,     0x00  ; standardni sinus
        db CHANNEL_1 + OPL_FREQUENCY_LOW,              0x41  ; frekvence zvuku (komorni A = 440 Hz)
        db CHANNEL_1 + OPL_KEY_ON,                     0x12  ; zapnuti/povoleni zvuku + nastaveni oktavy a vyssich bitu frekvence
        db CHANNEL_1 + OPL_FEEDBACK,                   0b00110001  ; volba AM-FM
        db 0, 0                                              ; zarazka
 
 
perform_write_to_opl_register:
        ; zapis do vybraneho registru OPL2 nebo OPL3
        ; AL - registr
        ; AH - hodnota
        mov dx, OPL_ADDRESS   ; vyber registru pro modifikaci
        out dx, al
 
        mov al, ah            ; zapis hodnoty do vybraneho registru
        mov dx, OPL_DATA
        out dx, al
 
        ret
 
 
perform_write_to_opl_high_register:
        ; zapis do vybraneho "vyssiho" registru OPL3
        ; AL - registr
        ; AH - hodnota
        mov dx, OPL_HIGH_ADDRESS   ; vyber registru pro modifikaci
        out dx, al
 
        mov al, ah                 ; zapis hodnoty do vybraneho registru
        mov dx, OPL_HIGH_DATA
        out dx, al
 
        ret

8. Vliv změny tvaru vlny na zvuk s FM syntézou

Oba demonstrační příklady, které jsme si doposud ukázali, měly první kanál přepnutý do režimu AM syntézy, takže se výstupy z jednotlivých operátorů přímo posílaly na D/A převodník. Ovšem tvar vlny má vliv i na tvorbu tónu s využitím FM syntézy. Můžeme si to ostatně snadno otestovat, protože FM režim je nastavený implicitně při (resp. po) resetu OPL3. Aby byl vliv FM ještě více patrný, pozměníme obálku (ADSR) obou operátorů tvořících první kanál. Tabulka s nastavením čipu OPL3 (konkrétně celého prvního kanálu) se pozmění následovně:

db CHANNEL_1_OPERATOR_1 + OPL_AMP_VIBRATO_EG,  0x01  ; nastaveni modulatoru: nasobeni frekvence jednickou
db CHANNEL_1_OPERATOR_1 + OPL_LEVEL,           0x00  ; uroven vystupu 40 dB
db CHANNEL_1_OPERATOR_1 + OPL_ATTACK_DECAY,    0x41  ; modulator: pomaly nastup zvuku + pomale doznivani
db CHANNEL_1_OPERATOR_1 + OPL_SUSTAIN_RELEASE, 0x7f  ; urovne sustain a release pro modulator
db CHANNEL_1_OPERATOR_2 + OPL_AMP_VIBRATO_EG,  0x01  ; nastaveni nosne: nasobeni frekvence jednickou
db CHANNEL_1_OPERATOR_2 + OPL_LEVEL,           0x00  ; nastaveni urovne vystupu nosne na 47 dB
db CHANNEL_1_OPERATOR_2 + OPL_ATTACK_DECAY,    0xa2  ; nosna: rychly nastup + pomale doznivani
db CHANNEL_1_OPERATOR_2 + OPL_SUSTAIN_RELEASE, 0x77  ; urovne sustain a release pro nosnou
db CHANNEL_1_OPERATOR_1 + OPL_WAVE_SELECT,     0x00  ; standardni sinus
db CHANNEL_1 + OPL_FREQUENCY_LOW,              0x41  ; frekvence zvuku (komorni A = 440 Hz)
db CHANNEL_1 + OPL_KEY_ON,                     0x12  ; zapnuti/povoleni zvuku + nastaveni oktavy a vyssich bitu frekvence
db 0, 0                                              ; zarazka

9. Úplný zdrojový kód dnešního třetího demonstračního příkladu

Dnešní třetí demonstrační příklad, který je odvozen od příkladu druhého (pouze se změnily hodnoty některých registrů s tvary obálky atd.), vypadá následovně:

; Prehrani zakladniho tonu na kartach s cipem OPL3.
; Prepnuti do rezimu OPL3.
; Prepinani tvaru vlny pro generovani zvuku.
; Pojmenovani registru OPL3.
; Vetsi zpetna vazba (feedback).
; Ovladani KEY ON mezernikem
; Tvar vlny je rizen klavesami 1 az 8
; Ukonceni aplikace stiskem ESC
;
;
; Tento demonstracni priklad je pouzity v serialu o programovani
; grafickych dem a her na PC v DOSu:
; https://www.root.cz/serialy/vyvoj-her-a-grafickych-dem-pro-platformu-pc/
;
;
; preklad pomoci:
;     nasm -f bin -o sounds_opl3_waveform_3.com sounds_opl3_waveform_3.asm
;
; nebo pouze:
;     nasm -o sounds_opl3_waveform_3.com sounds_opl3_waveform_3.asm
 
;-----------------------------------------------------------------------------
 
BITS 16         ; 16bitovy vystup pro DOS
CPU 8086        ; specifikace pouziteho instrukcniho souboru
 
 
;-----------------------------------------------------------------------------
 
; registry karet s cipem OPL3
OPL_ADDRESS           equ 0x220
OPL_DATA              equ 0x221
OPL_HIGH_ADDRESS      equ 0x222
OPL_HIGH_DATA         equ 0x223
 
; ridici registry OPL2
OPL_TEST_LSI          equ 0x01
OPL_TIMER_1           equ 0x02
OPL_TIMER_2           equ 0x03
OPL_TIMER_CTRL        equ 0x04
OPL_KBSPLIT           equ 0x08
OPL_AMP_VIBRATO_EG    equ 0x20
OPL_LEVEL             equ 0x40
OPL_ATTACK_DECAY      equ 0x60
OPL_SUSTAIN_RELEASE   equ 0x80
OPL_FREQUENCY_LOW     equ 0xa0
OPL_KEY_ON            equ 0xb0
OPL_AM_VIBRATO_RHYTHM equ 0xbd
OPL_FEEDBACK          equ 0xc0
OPL_WAVE_SELECT       equ 0xe0
OPL3_MODE_ENABLE      equ 0x05  ; vyssi port!!!
 
; indexy kanalu
CHANNEL_1 equ 0
CHANNEL_2 equ 1
CHANNEL_3 equ 2
CHANNEL_4 equ 3
CHANNEL_5 equ 4
CHANNEL_6 equ 5
CHANNEL_7 equ 6
CHANNEL_8 equ 7
CHANNEL_9 equ 8
 
; offsety pro jednotlive operatory
; --------------------------------------------------
;  Channel        1   2   3   4   5   6   7   8   9
;  Operator 1    00  01  02  08  09  0A  10  11  12
;  Operator 2    03  04  05  0B  0C  0D  13  14  15
; --------------------------------------------------
;  Channel        1   2   3   4   5   6   7   8   9
CHANNEL_1_OPERATOR_1 equ 0x00
CHANNEL_1_OPERATOR_2 equ 0x03
CHANNEL_2_OPERATOR_1 equ 0x01
CHANNEL_2_OPERATOR_2 equ 0x04
CHANNEL_3_OPERATOR_1 equ 0x02
CHANNEL_3_OPERATOR_2 equ 0x05
CHANNEL_4_OPERATOR_1 equ 0x08
CHANNEL_4_OPERATOR_2 equ 0x0b
CHANNEL_5_OPERATOR_1 equ 0x09
CHANNEL_5_OPERATOR_2 equ 0x0c
CHANNEL_6_OPERATOR_1 equ 0x0a
CHANNEL_6_OPERATOR_2 equ 0x0d
CHANNEL_7_OPERATOR_1 equ 0x10
CHANNEL_7_OPERATOR_2 equ 0x13
CHANNEL_8_OPERATOR_1 equ 0x11
CHANNEL_8_OPERATOR_2 equ 0x14
CHANNEL_9_OPERATOR_1 equ 0x12
CHANNEL_9_OPERATOR_2 equ 0x15
 
; registry PPI
PPI_PORT_A equ 0x60
PPI_PORT_B equ 0x61
 
; kody klaves
KEY_ESC     equ 0x01
KEY_SPACE   equ 0x39
KEY_RELEASE equ 0x80
KEY_1       equ 0x02
KEY_8       equ KEY_1 + 8
 
 
;-----------------------------------------------------------------------------
 
; ukonceni procesu a navrat do DOSu
%macro exit 0
        ret
%endmacro
 
; makro pro zapis do registru OPL2 nebo OPL3
%macro write_opl_register 2
        mov     al, %1
        mov     ah, %2
        call    perform_write_to_opl_register
%endmacro
 
; makro pro zapis do "vyssiho" registru OPL3
%macro write_opl_high_register 2
        mov     al, %1
        mov     ah, %2
        call    perform_write_to_opl_high_register
%endmacro
 
;-----------------------------------------------------------------------------
org  0x100        ; zacatek kodu pro programy typu COM (vzdy se zacina na 256)
 
start:
        push cs
        pop  ds                          ; DS==CS
 
        write_opl_high_register OPL3_MODE_ENABLE, 1
 
        mov  si, tone1                   ; zacatek tabulky
        call write_table_to_opl3         ; zapis obsahu tabulky do OPL3
 
        in  al, PPI_PORT_B               ; port B s rizenim zarizeni
        or  al, 0b1000000                ; nastaveni bitu cislo 7 na jednicku
        out PPI_PORT_B, al               ; zapis zpet na port B
 
.opak:
        in  al, PPI_PORT_A               ; cteni stisknute klavesy
        cmp al, KEY_SPACE                ; test na stisk mezerniku
        jne .next_test_1                 ; neni stisknut -> preskok
        write_opl_register CHANNEL_1 + OPL_KEY_ON, 0x32    ; povoleni KEY ON bitu
        jmp .opak
.next_test_1:
        cmp al, KEY_SPACE + KEY_RELEASE  ; test na pusteni mezerniku
        jne .next_test_2                 ; neni pusten -> dalsi test
        write_opl_register CHANNEL_1 + OPL_KEY_ON, 0x12    ; zakaz KEY ON bitu
        jmp .opak
.next_test_2:
        cmp al, KEY_1                    ; test na numericke klavesy
        jb  .next_test_3                 ; hodnota "pod" kodem klavesy 1
        cmp al, KEY_8
        ja  .next_test_3                 ; hodnota "nad" kodem klavesy 8
        mov bl, al                       ; makro prepisuje AL -> nemuzeme ho primo pouzit
        sub bl, KEY_1
        write_opl_register CHANNEL_1_OPERATOR_1 + OPL_WAVE_SELECT, bl
        jmp .opak
.next_test_3:
        cmp al, KEY_ESC                  ; test stisknute klavesy ESC
        jne .opak                        ; neni stisknuta? -> zkusme znovu
 
        exit
 
write_table_to_opl3:
        lodsb                            ; nacist bajt z tabulky (cislo registru)
        or  al, al                       ; test na nulu
        jnz .write_register
        ret                              ; dosahli jsme konce tabulky
.write_register:
        mov ah, al
        lodsb                            ; nacist dalsi bajt z tabulky (hodnota registru)
        xchg al, ah                      ; podprogram vyzaduje opacne poradi AL, AH
        call perform_write_to_opl_register
        jmp  write_table_to_opl3         ; muzeme prejit na dalsi registr
 
 
tone1:  ; tabulka s tonem pro prvni kanal
        db CHANNEL_1_OPERATOR_1 + OPL_AMP_VIBRATO_EG,  0x01  ; nastaveni modulatoru: nasobeni frekvence jednickou
        db CHANNEL_1_OPERATOR_1 + OPL_LEVEL,           0x00  ; uroven vystupu 40 dB
        db CHANNEL_1_OPERATOR_1 + OPL_ATTACK_DECAY,    0x41  ; modulator: pomaly nastup zvuku + pomale doznivani
        db CHANNEL_1_OPERATOR_1 + OPL_SUSTAIN_RELEASE, 0x7f  ; urovne sustain a release pro modulator
        db CHANNEL_1_OPERATOR_2 + OPL_AMP_VIBRATO_EG,  0x01  ; nastaveni nosne: nasobeni frekvence jednickou
        db CHANNEL_1_OPERATOR_2 + OPL_LEVEL,           0x00  ; nastaveni urovne vystupu nosne na 47 dB
        db CHANNEL_1_OPERATOR_2 + OPL_ATTACK_DECAY,    0xa2  ; nosna: rychly nastup + pomale doznivani
        db CHANNEL_1_OPERATOR_2 + OPL_SUSTAIN_RELEASE, 0x77  ; urovne sustain a release pro nosnou
        db CHANNEL_1_OPERATOR_1 + OPL_WAVE_SELECT,     0x00  ; standardni sinus
        db CHANNEL_1 + OPL_FREQUENCY_LOW,              0x41  ; frekvence zvuku (komorni A = 440 Hz)
        db CHANNEL_1 + OPL_KEY_ON,                     0x12  ; zapnuti/povoleni zvuku + nastaveni oktavy a vyssich bitu frekvence
        db 0, 0                                              ; zarazka
 
 
perform_write_to_opl_register:
        ; zapis do vybraneho registru OPL2 nebo OPL3
        ; AL - registr
        ; AH - hodnota
        mov dx, OPL_ADDRESS   ; vyber registru pro modifikaci
        out dx, al
 
        mov al, ah            ; zapis hodnoty do vybraneho registru
        mov dx, OPL_DATA
        out dx, al
 
        ret
 
 
perform_write_to_opl_high_register:
        ; zapis do vybraneho "vyssiho" registru OPL3
        ; AL - registr
        ; AH - hodnota
        mov dx, OPL_HIGH_ADDRESS   ; vyber registru pro modifikaci
        out dx, al
 
        mov al, ah                 ; zapis hodnoty do vybraneho registru
        mov dx, OPL_HIGH_DATA
        out dx, al
 
        ret

10. Modifikace tvaru nosné vlny i modulátoru

Prozatím jsme po zapnutí FM syntézy měnili pouze tvar vlny pro první operátor. Při FM syntéze je tento operátor použit jako modulátor nosné vlny. Ovšem pochopitelně nám nic nebrání v tom, abychom pozměnili i tvar nosné vlny. U čipu OPL2 tedy máme k dispozici čtyři možné kombinace, u čipu OPL3 se jedná o 8×8=64 možných kombinací tvarů vln. V dalším demonstračním příkladu se tvar vlny modulátoru stále ovládá klávesami 1–8, kdežto tvar nosné vlny (carrier) se mění klávesami Q-I. V assembleru je vše realizováno následujícím způsobem:

.opak:
        in  al, PPI_PORT_A               ; cteni stisknute klavesy
        cmp al, KEY_SPACE                ; test na stisk mezerniku
        jne .next_test_1                 ; neni stisknut -> preskok
        write_opl_register CHANNEL_1 + OPL_KEY_ON, 0x32    ; povoleni KEY ON bitu
        jmp .opak
.next_test_1:
        cmp al, KEY_SPACE + KEY_RELEASE  ; test na pusteni mezerniku
        jne .next_test_2                 ; neni pusten -> dalsi test
        write_opl_register CHANNEL_1 + OPL_KEY_ON, 0x12    ; zakaz KEY ON bitu
        jmp .opak
.next_test_2:
        cmp al, KEY_1                    ; test na numericke klavesy
        jb  .next_test_3                 ; hodnota "pod" kodem klavesy 1
        cmp al, KEY_8
        ja  .next_test_3                 ; hodnota "nad" kodem klavesy 8
        mov bl, al                       ; makro prepisuje AL -> nemuzeme ho primo pouzit
        sub bl, KEY_1
        write_opl_register CHANNEL_1_OPERATOR_1 + OPL_WAVE_SELECT, bl
        jmp .opak
.next_test_3:
        cmp al, KEY_Q                    ; test na dalsi radu klaves
        jb  .next_test_4                 ; hodnota "pod" kodem klavesy Q
        cmp al, KEY_I
        ja  .next_test_4                 ; hodnota "nad" kodem klavesy I
        mov bl, al                       ; makro prepisuje AL -> nemuzeme ho primo pouzit
        sub bl, KEY_Q
        write_opl_register CHANNEL_1_OPERATOR_2 + OPL_WAVE_SELECT, bl
        jmp .opak
.next_test_4:

11. Úplný zdrojový kód dnešního čtvrtého demonstračního příkladu

Další části příkladu se již nemění, takže se jen v krátkosti podívejme na jeho kód:

; Prehrani zakladniho tonu na kartach s cipem OPL3.
; Prepnuti do rezimu OPL3.
; Prepinani tvaru vlny pro generovani zvuku.
; Pojmenovani registru OPL3.
; Vetsi zpetna vazba (feedback).
; Ovladani KEY ON mezernikem
; Tvar vlny prvniho operatoru je rizen klavesami 1 az 8
; Tvar vlny druheho operatoru je rizen klavesami Q az I
; Ukonceni aplikace stiskem ESC
;
;
; Tento demonstracni priklad je pouzity v serialu o programovani
; grafickych dem a her na PC v DOSu:
; https://www.root.cz/serialy/vyvoj-her-a-grafickych-dem-pro-platformu-pc/
;
;
; preklad pomoci:
;     nasm -f bin -o sounds_opl3_waveform_4.com sounds_opl3_waveform_4.asm
;
; nebo pouze:
;     nasm -o sounds_opl3_waveform_4.com sounds_opl3_waveform_4.asm
 
;-----------------------------------------------------------------------------
 
BITS 16         ; 16bitovy vystup pro DOS
CPU 8086        ; specifikace pouziteho instrukcniho souboru
 
 
;-----------------------------------------------------------------------------
 
; registry karet s cipem OPL3
OPL_ADDRESS           equ 0x220
OPL_DATA              equ 0x221
OPL_HIGH_ADDRESS      equ 0x222
OPL_HIGH_DATA         equ 0x223
 
; ridici registry OPL2
OPL_TEST_LSI          equ 0x01
OPL_TIMER_1           equ 0x02
OPL_TIMER_2           equ 0x03
OPL_TIMER_CTRL        equ 0x04
OPL_KBSPLIT           equ 0x08
OPL_AMP_VIBRATO_EG    equ 0x20
OPL_LEVEL             equ 0x40
OPL_ATTACK_DECAY      equ 0x60
OPL_SUSTAIN_RELEASE   equ 0x80
OPL_FREQUENCY_LOW     equ 0xa0
OPL_KEY_ON            equ 0xb0
OPL_AM_VIBRATO_RHYTHM equ 0xbd
OPL_FEEDBACK          equ 0xc0
OPL_WAVE_SELECT       equ 0xe0
OPL3_MODE_ENABLE      equ 0x05  ; vyssi port!!!
 
; indexy kanalu
CHANNEL_1 equ 0
CHANNEL_2 equ 1
CHANNEL_3 equ 2
CHANNEL_4 equ 3
CHANNEL_5 equ 4
CHANNEL_6 equ 5
CHANNEL_7 equ 6
CHANNEL_8 equ 7
CHANNEL_9 equ 8
 
; offsety pro jednotlive operatory
; --------------------------------------------------
;  Channel        1   2   3   4   5   6   7   8   9
;  Operator 1    00  01  02  08  09  0A  10  11  12
;  Operator 2    03  04  05  0B  0C  0D  13  14  15
; --------------------------------------------------
;  Channel        1   2   3   4   5   6   7   8   9
CHANNEL_1_OPERATOR_1 equ 0x00
CHANNEL_1_OPERATOR_2 equ 0x03
CHANNEL_2_OPERATOR_1 equ 0x01
CHANNEL_2_OPERATOR_2 equ 0x04
CHANNEL_3_OPERATOR_1 equ 0x02
CHANNEL_3_OPERATOR_2 equ 0x05
CHANNEL_4_OPERATOR_1 equ 0x08
CHANNEL_4_OPERATOR_2 equ 0x0b
CHANNEL_5_OPERATOR_1 equ 0x09
CHANNEL_5_OPERATOR_2 equ 0x0c
CHANNEL_6_OPERATOR_1 equ 0x0a
CHANNEL_6_OPERATOR_2 equ 0x0d
CHANNEL_7_OPERATOR_1 equ 0x10
CHANNEL_7_OPERATOR_2 equ 0x13
CHANNEL_8_OPERATOR_1 equ 0x11
CHANNEL_8_OPERATOR_2 equ 0x14
CHANNEL_9_OPERATOR_1 equ 0x12
CHANNEL_9_OPERATOR_2 equ 0x15
 
; registry PPI
PPI_PORT_A equ 0x60
PPI_PORT_B equ 0x61
 
; kody klaves
KEY_ESC     equ 0x01
KEY_SPACE   equ 0x39
KEY_RELEASE equ 0x80
KEY_1       equ 0x02
KEY_8       equ KEY_1 + 8
KEY_Q       equ 0x10
KEY_W       equ 0x11
KEY_E       equ 0x12
KEY_R       equ 0x13
KEY_T       equ 0x14
KEY_Y       equ 0x15
KEY_U       equ 0x16
KEY_I       equ 0x17
 
 
;-----------------------------------------------------------------------------
 
; ukonceni procesu a navrat do DOSu
%macro exit 0
        ret
%endmacro
 
; makro pro zapis do registru OPL2 nebo OPL3
%macro write_opl_register 2
        mov     al, %1
        mov     ah, %2
        call    perform_write_to_opl_register
%endmacro
 
; makro pro zapis do "vyssiho" registru OPL3
%macro write_opl_high_register 2
        mov     al, %1
        mov     ah, %2
        call    perform_write_to_opl_high_register
%endmacro
 
;-----------------------------------------------------------------------------
org  0x100        ; zacatek kodu pro programy typu COM (vzdy se zacina na 256)
 
start:
        push cs
        pop  ds                          ; DS==CS
 
        write_opl_high_register OPL3_MODE_ENABLE, 1
 
        mov  si, tone1                   ; zacatek tabulky
        call write_table_to_opl3         ; zapis obsahu tabulky do OPL3
 
        in  al, PPI_PORT_B               ; port B s rizenim zarizeni
        or  al, 0b1000000                ; nastaveni bitu cislo 7 na jednicku
        out PPI_PORT_B, al               ; zapis zpet na port B
 
.opak:
        in  al, PPI_PORT_A               ; cteni stisknute klavesy
        cmp al, KEY_SPACE                ; test na stisk mezerniku
        jne .next_test_1                 ; neni stisknut -> preskok
        write_opl_register CHANNEL_1 + OPL_KEY_ON, 0x32    ; povoleni KEY ON bitu
        jmp .opak
.next_test_1:
        cmp al, KEY_SPACE + KEY_RELEASE  ; test na pusteni mezerniku
        jne .next_test_2                 ; neni pusten -> dalsi test
        write_opl_register CHANNEL_1 + OPL_KEY_ON, 0x12    ; zakaz KEY ON bitu
        jmp .opak
.next_test_2:
        cmp al, KEY_1                    ; test na numericke klavesy
        jb  .next_test_3                 ; hodnota "pod" kodem klavesy 1
        cmp al, KEY_8
        ja  .next_test_3                 ; hodnota "nad" kodem klavesy 8
        mov bl, al                       ; makro prepisuje AL -> nemuzeme ho primo pouzit
        sub bl, KEY_1
        write_opl_register CHANNEL_1_OPERATOR_1 + OPL_WAVE_SELECT, bl
        jmp .opak
.next_test_3:
        cmp al, KEY_Q                    ; test na dalsi radu klaves
        jb  .next_test_4                 ; hodnota "pod" kodem klavesy Q
        cmp al, KEY_I
        ja  .next_test_4                 ; hodnota "nad" kodem klavesy I
        mov bl, al                       ; makro prepisuje AL -> nemuzeme ho primo pouzit
        sub bl, KEY_Q
        write_opl_register CHANNEL_1_OPERATOR_2 + OPL_WAVE_SELECT, bl
        jmp .opak
.next_test_4:
        cmp al, KEY_ESC                  ; test stisknute klavesy ESC
        jne .opak                        ; neni stisknuta? -> zkusme znovu
 
        exit
 
write_table_to_opl3:
        lodsb                            ; nacist bajt z tabulky (cislo registru)
        or  al, al                       ; test na nulu
        jnz .write_register
        ret                              ; dosahli jsme konce tabulky
.write_register:
        mov ah, al
        lodsb                            ; nacist dalsi bajt z tabulky (hodnota registru)
        xchg al, ah                      ; podprogram vyzaduje opacne poradi AL, AH
        call perform_write_to_opl_register
        jmp  write_table_to_opl3         ; muzeme prejit na dalsi registr
 
 
tone1:  ; tabulka s tonem pro prvni kanal
        db CHANNEL_1_OPERATOR_1 + OPL_AMP_VIBRATO_EG,  0x01  ; nastaveni modulatoru: nasobeni frekvence jednickou
        db CHANNEL_1_OPERATOR_1 + OPL_LEVEL,           0x00  ; uroven vystupu 40 dB
        db CHANNEL_1_OPERATOR_1 + OPL_ATTACK_DECAY,    0x41  ; modulator: pomaly nastup zvuku + pomale doznivani
        db CHANNEL_1_OPERATOR_1 + OPL_SUSTAIN_RELEASE, 0x7f  ; urovne sustain a release pro modulator
        db CHANNEL_1_OPERATOR_2 + OPL_AMP_VIBRATO_EG,  0x01  ; nastaveni nosne: nasobeni frekvence jednickou
        db CHANNEL_1_OPERATOR_2 + OPL_LEVEL,           0x00  ; nastaveni urovne vystupu nosne na 47 dB
        db CHANNEL_1_OPERATOR_2 + OPL_ATTACK_DECAY,    0xa2  ; nosna: rychly nastup + pomale doznivani
        db CHANNEL_1_OPERATOR_2 + OPL_SUSTAIN_RELEASE, 0x77  ; urovne sustain a release pro nosnou
        db CHANNEL_1_OPERATOR_1 + OPL_WAVE_SELECT,     0x00  ; standardni sinus
        db CHANNEL_1_OPERATOR_2 + OPL_WAVE_SELECT,     0x00  ; standardni sinus
        db CHANNEL_1 + OPL_FREQUENCY_LOW,              0x41  ; frekvence zvuku (komorni A = 440 Hz)
        db CHANNEL_1 + OPL_KEY_ON,                     0x12  ; zapnuti/povoleni zvuku + nastaveni oktavy a vyssich bitu frekvence
        db 0, 0                                              ; zarazka
 
 
perform_write_to_opl_register:
        ; zapis do vybraneho registru OPL2 nebo OPL3
        ; AL - registr
        ; AH - hodnota
        mov dx, OPL_ADDRESS   ; vyber registru pro modifikaci
        out dx, al
 
        mov al, ah            ; zapis hodnoty do vybraneho registru
        mov dx, OPL_DATA
        out dx, al
 
        ret
 
 
perform_write_to_opl_high_register:
        ; zapis do vybraneho "vyssiho" registru OPL3
        ; AL - registr
        ; AH - hodnota
        mov dx, OPL_HIGH_ADDRESS   ; vyber registru pro modifikaci
        out dx, al
 
        mov al, ah                 ; zapis hodnoty do vybraneho registru
        mov dx, OPL_HIGH_DATA
        out dx, al
 
        ret

12. Režim, ve kterém je jeden kanál tvořen čtyřmi operátory

Konečně se dostáváme k další důležité vlastnosti čipů OPL3. Tyto čipy totiž dokážou některé kanály spojit dohromady a získat tak kanály, které mají namísto pouhých dvou operátorů operátory čtyři. Ovšem nelze takto spojit všechny kanály – maximálně je možné dosáhnout stavu, že budeme mít k dispozici šest kanálů se čtyřmi operátory, přičemž zbytek kanálů je použit buď v dvouoperátorovém režimu nebo se využijí pro perkusní nástroje:

1. 18 kanálů, z nichž každý obsahuje dva operátory („dvojitý“ OPL2)
2. 15 melodických kanálů se dvěma operátory + pět kanálů pro perkusní režim
3. Až 6 kanálů se čtyřmi operátory + zbytek (minimálně 6 kanálů) se dvěma operátory
4. Až 6 kanálů se čtyřmi operátory + pět kanálů pro perkusní režim + zbytek kanály se dvěma operátory

Dnes se zaměříme na spojení prvního a druhého kanálu do nového kanálu se čtyřmi operátory. Zbytek nás nemusí zajímat – takže se vlastně pohybujeme ve třetí a čtvrté skupině.

13. Realizace spojení kanálů tak, aby byly k dispozici čtyři operátory

Ve výchozím nastavení je čip OPL3 přepnutý do režimu, ve kterém má každý kanál k dispozici pouze dva operátory a perkusní režim je zakázán. To v praxi znamená, že tón může být tvořen 18 kanály (celkový počet operátorů je stále roven 36), což jsme si již ostatně ukázali minule při naprogramování „kláves“ s 2×8 notami. Pokud budeme chtít některé kanály spojit takovým způsobem, aby se daly použít čtyři operátory, je nutné korektně nastavit registr 0×104, tedy registr z horní sady 256 řídicích registrů:

OPL_FOUR_OPERATOR_ENABLE equ 0x04 ; vyssi port!!!

V tomto registru má význam spodních šest bitů, protože můžeme vytvořit maximálně šest čtyřoperátorových kanálů:

Spojení kanálů 1 a 4 realizujeme zavoláním makra:

        write_opl_high_register OPL_FOUR_OPERATOR_ENABLE, 0b00000001

Offsety jednotlivých operátorů v kanálu se čtyřmi operátory se vypočtou podle tabulky:

;  Channel        1   2   3  10  11  12
;  Operator 1    00  01  02  12  13  14
;  Operator 2    03  04  05  15  16  17
;  Operator 3    08  09  0a  18  19  1a
;  Operator 4    0b  0c  0d  1b  1c  1d
; --------------------------------------------------

V našem konkrétním případě si tedy vystačíme s operátory 0, 3, 8 a 0×b.

14. Způsoby vzájemného propojení čtyř operátorů (algoritmy)

U již výše zmíněného syntetizéru Yamaha DX7 se používá označení algoritmus (viz též https://www.tinyloops.com/doc/y­amaha_dx7/algorithm-building-blocks.html) pro nastavení způsobu vzájemného propojení operátorů. V případě čipu OPL3 ovšem nemáme k dispozici 6 operátorů, ale pouze čtyři operátory. Navíc si si ale můžeme vybrat, jaký typ syntézy (AM či FM) se bude realizovat. Jednotlivé způsoby propojení je možné vizualizovat následovně:

   a) FM-FM Mode
 
    ┌───────┐      ┌───────┐      ┌───────┐      ┌───────┐
    │       │      │       │      │       │      │       │
    │ Op. 1 ├─────>│ Op. 2 ├─────>│ Op. 3 ├─────>│ Op. 4 ├─────> Output
    │       │      │       │      │       │      │       │
    └───────┘      └───────┘      └───────┘      └───────┘
 
   b) AM-FM Mode
 
    ┌───────┐
    │       │
    │ Op. 1 ├───────────────────────────────────┐
    │       │                                   │
    └───────┘                                   │
                            │
    ┌───────┐      ┌───────┐      ┌───────┐     │
    │       │      │       │      │       │     │
    │ Op. 2 ├─────>│ Op. 3 ├─────>│ Op. 4 ├─────┴─────> Output
    │       │      │       │      │       │
    └───────┘      └───────┘      └───────┘
 
   c) FM-AM Mode
 
    ┌───────┐      ┌───────┐
    │       │      │       │
    │ Op. 1 ├─────>│ Op. 2 ├─────┐
    │       │      │       │     │
    └───────┘      └───────┘     │
                     ├─────> Output
    ┌───────┐      ┌───────┐     │
    │       │      │       │     │
    │ Op. 3 ├─────>│ Op. 4 ├─────┘
    │       │      │       │
    └───────┘      └───────┘
 
   d) AM-AM Mode
 
    ┌───────┐
    │       │
    │ Op. 1 ├────────────────────┐
    │       │                    │
    └───────┘                    │
                     │
    ┌───────┐      ┌───────┐     │
    │       │      │       │     │
    │ Op. 2 ├─────>│ Op. 3 ├─────┼─────> Output
    │       │      │       │     │
    └───────┘      └───────┘     │
                     │
    ┌───────┐                    │
    │       │                    │
    │ Op. 4 ├────────────────────┘
    │       │
    └───────┘

Zdroj: https://moddingwiki.shika­di.net/wiki/OPL_chip#Four-operator_%22Mess%22_Modula­tion_Synthesis.

15. Interaktivní přepínání AM a FM režimů u kanálu se čtyřmi operátory

V případě, že je první kanál nakonfigurován takovým způsobem, že je složen ze čtyř operátorů, volí se kombinace AM a FM syntézy s využitím registrů OPL_FEEDBACK rezervovaných pro první a čtvrtý kanál. Proč tomu tak je? „Čtyřoperátorový“ první kanál totiž vznikne spojením dvou původních „dvouoperátorových“ kanálů, a to konkrétně kanálů 1 a 4, což jsme si již ukázali v tabulce uvedené ve třinácté kapitole.

Volba AM/FM je vybírána nultým bitem registru OPL_FEEDBACK:

db CHANNEL_1 + OPL_FEEDBACK,                   0b00110000  ; volba AM-FM
db CHANNEL_1 + OPL_FEEDBACK + 3,               0b00110000  ; volba AM-FM

S významem (0 a 1 zde značí nultý bit registru OPL_FEEDBACK):

Tuto dvojici bitů budeme interaktivně ovládat klávesami 1 až 4 (1/2 – výběr prvního sloupce, 3/4 – výběr druhého sloupce). Samotná realizace je celkem snadná:

        cmp al, KEY_1
        jne .next_test_3
        write_opl_register CHANNEL_1 + OPL_FEEDBACK, 0b00110000 ; FM
        jmp .opak
.next_test_3:
        cmp al, KEY_2
        jne .next_test_4
        write_opl_register CHANNEL_1 + OPL_FEEDBACK, 0b00110001 ; AM
        jmp .opak
.next_test_4:
        cmp al, KEY_3
        jne .next_test_5
        write_opl_register CHANNEL_1 + OPL_FEEDBACK + 3, 0b00110000 ; FM
        jmp .opak
.next_test_5:
        cmp al, KEY_4
        jne .next_test_6
        write_opl_register CHANNEL_1 + OPL_FEEDBACK + 3, 0b00110001 ; AM
        jmp .opak
.next_test_6:

16. Úplný zdrojový kód dnešního pátého demonstračního příkladu

Výše popsané interaktivní přepínání AM a FM režimů u jediného (prvního) kanálu nakonfigurovaného tak, že využívá čtyři operátory, je realizováno v dnešním posledním demonstračním příkladu, jehož zdrojový kód vypadá následovně:

; Prehrani tonu s vyuzitim 4 operatoru na kartach s cipem OPL3.
; Prepnuti do rezimu OPL3.
; Pojmenovani registru OPL3.
; Vetsi zpetna vazba (feedback).
; Ovladani KEY ON mezernikem
; Ukonceni aplikace stiskem ESC
;
;
; Tento demonstracni priklad je pouzity v serialu o programovani
; grafickych dem a her na PC v DOSu:
; https://www.root.cz/serialy/vyvoj-her-a-grafickych-dem-pro-platformu-pc/
;
;
; preklad pomoci:
;     nasm -f bin -o sounds_opl3_4operators_1.com sounds_opl3_4operators_1.asm
;
; nebo pouze:
;     nasm -o sounds_opl3_4operators_1.com sounds_opl3_4operators_1.asm
 
;-----------------------------------------------------------------------------
 
BITS 16         ; 16bitovy vystup pro DOS
CPU 8086        ; specifikace pouziteho instrukcniho souboru
 
 
;-----------------------------------------------------------------------------
 
; registry karet s cipem OPL3
OPL_ADDRESS           equ 0x220
OPL_DATA              equ 0x221
OPL_HIGH_ADDRESS      equ 0x222
OPL_HIGH_DATA         equ 0x223
 
; ridici registry OPL2
OPL_TEST_LSI             equ 0x01
OPL_TIMER_1              equ 0x02
OPL_TIMER_2              equ 0x03
OPL_TIMER_CTRL           equ 0x04
OPL_KBSPLIT              equ 0x08
OPL_AMP_VIBRATO_EG       equ 0x20
OPL_LEVEL                equ 0x40
OPL_ATTACK_DECAY         equ 0x60
OPL_SUSTAIN_RELEASE      equ 0x80
OPL_FREQUENCY_LOW        equ 0xa0
OPL_KEY_ON               equ 0xb0
OPL_AM_VIBRATO_RHYTHM    equ 0xbd
OPL_FEEDBACK             equ 0xc0
OPL_WAVE_SELECT          equ 0xe0
OPL_FOUR_OPERATOR_ENABLE equ 0x04 ; vyssi port!!!
OPL3_MODE_ENABLE         equ 0x05 ; vyssi port!!!
 
; indexy kanalu
CHANNEL_1 equ 0
CHANNEL_2 equ 1
CHANNEL_3 equ 2
CHANNEL_4 equ 3
CHANNEL_5 equ 4
CHANNEL_6 equ 5
CHANNEL_7 equ 6
CHANNEL_8 equ 7
CHANNEL_9 equ 8
 
; offsety pro jednotlive operatory v rezimu dvou operatoru
; --------------------------------------------------
;  Channel        1   2   3   4   5   6   7   8   9
;  Operator 1    00  01  02  08  09  0A  10  11  12
;  Operator 2    03  04  05  0B  0C  0D  13  14  15
; --------------------------------------------------
;  Channel        1   2   3   4   5   6   7   8   9
 
; offsety pro jednotlive operatory v rezimu ctyr operatoru
; --------------------------------------------------
;  Channel        1   2   3  10  11  12
;  Operator 1    00  01  02  12  13  14
;  Operator 2    03  04  05  15  16  17
;  Operator 3    08  09  0a  18  19  1a
;  Operator 4    0b  0c  0d  1b  1c  1d
; --------------------------------------------------
;  Channel        1   2   3  10  11  12
CHANNEL_1_OPERATOR_1 equ 0x00
CHANNEL_1_OPERATOR_2 equ 0x03
CHANNEL_1_OPERATOR_3 equ 0x08
CHANNEL_1_OPERATOR_4 equ 0x0b
CHANNEL_2_OPERATOR_1 equ 0x01
CHANNEL_2_OPERATOR_2 equ 0x04
CHANNEL_3_OPERATOR_1 equ 0x02
CHANNEL_3_OPERATOR_2 equ 0x05
CHANNEL_4_OPERATOR_1 equ 0x08
CHANNEL_4_OPERATOR_2 equ 0x0b
CHANNEL_5_OPERATOR_1 equ 0x09
CHANNEL_5_OPERATOR_2 equ 0x0c
CHANNEL_6_OPERATOR_1 equ 0x0a
CHANNEL_6_OPERATOR_2 equ 0x0d
CHANNEL_7_OPERATOR_1 equ 0x10
CHANNEL_7_OPERATOR_2 equ 0x13
CHANNEL_8_OPERATOR_1 equ 0x11
CHANNEL_8_OPERATOR_2 equ 0x14
CHANNEL_9_OPERATOR_1 equ 0x12
CHANNEL_9_OPERATOR_2 equ 0x15
 
; registry PPI
PPI_PORT_A equ 0x60
PPI_PORT_B equ 0x61
 
; kody klaves
KEY_ESC     equ 0x01
KEY_SPACE   equ 0x39
KEY_RELEASE equ 0x80
KEY_1       equ 0x02
KEY_2       equ 0x03
KEY_3       equ 0x04
KEY_4       equ 0x05
 
 
;-----------------------------------------------------------------------------
 
; ukonceni procesu a navrat do DOSu
%macro exit 0
        ret
%endmacro
 
; makro pro zapis do registru OPL2 nebo OPL3
%macro write_opl_register 2
        mov     al, %1
        mov     ah, %2
        call    perform_write_to_opl_register
%endmacro
 
; makro pro zapis do "vyssiho" registru OPL3
%macro write_opl_high_register 2
        mov     al, %1
        mov     ah, %2
        call    perform_write_to_opl_high_register
%endmacro
 
;-----------------------------------------------------------------------------
org  0x100        ; zacatek kodu pro programy typu COM (vzdy se zacina na 256)
 
start:
        push cs
        pop  ds                          ; DS==CS
 
        write_opl_high_register OPL3_MODE_ENABLE, 1
        write_opl_high_register OPL_FOUR_OPERATOR_ENABLE, 0b00000001
 
        mov  si, tone1                   ; zacatek tabulky
        call write_table_to_opl3         ; zapis obsahu tabulky do OPL3
 
        in  al, PPI_PORT_B               ; port B s rizenim zarizeni
        or  al, 0b1000000                ; nastaveni bitu cislo 7 na jednicku
        out PPI_PORT_B, al               ; zapis zpet na port B
 
.opak:
        in  al, PPI_PORT_A               ; cteni stisknute klavesy
        cmp al, KEY_SPACE                ; test na stisk mezerniku
        jne .next_test_1                 ; neni stisknut -> preskok
        write_opl_register CHANNEL_1 + OPL_KEY_ON, 0x32    ; povoleni KEY ON bitu
        jmp .opak
.next_test_1:
        cmp al, KEY_SPACE + KEY_RELEASE  ; test na pusteni mezerniku
        jne .next_test_2                 ; neni pusten -> dalsi test
        write_opl_register CHANNEL_1 + OPL_KEY_ON, 0x12    ; zakaz KEY ON bitu
        jmp .opak
.next_test_2:
        cmp al, KEY_1
        jne .next_test_3
        write_opl_register CHANNEL_1 + OPL_FEEDBACK, 0b00110000 ; FM
        jmp .opak
.next_test_3:
        cmp al, KEY_2
        jne .next_test_4
        write_opl_register CHANNEL_1 + OPL_FEEDBACK, 0b00110001 ; AM
        jmp .opak
.next_test_4:
        cmp al, KEY_3
        jne .next_test_5
        write_opl_register CHANNEL_1 + OPL_FEEDBACK + 3, 0b00110000 ; FM
        jmp .opak
.next_test_5:
        cmp al, KEY_4
        jne .next_test_6
        write_opl_register CHANNEL_1 + OPL_FEEDBACK + 3, 0b00110001 ; AM
        jmp .opak
.next_test_6:
        cmp al, KEY_ESC                  ; test stisknute klavesy ESC
        jne .opak                        ; neni stisknuta? -> zkusme znovu
 
        exit
 
 
write_table_to_opl3:
        lodsb                            ; nacist bajt z tabulky (cislo registru)
        or  al, al                       ; test na nulu
        jnz .write_register
        ret                              ; dosahli jsme konce tabulky
.write_register:
        mov ah, al
        lodsb                            ; nacist dalsi bajt z tabulky (hodnota registru)
        xchg al, ah                      ; podprogram vyzaduje opacne poradi AL, AH
        call perform_write_to_opl_register
        jmp  write_table_to_opl3         ; muzeme prejit na dalsi registr
 
 
tone1:  ; tabulka s tonem pro prvni kanal
        db CHANNEL_1_OPERATOR_1 + OPL_AMP_VIBRATO_EG,  0x01  ; nastaveni modulatoru: nasobeni frekvence jednickou
        db CHANNEL_1_OPERATOR_1 + OPL_LEVEL,           0x00  ; uroven vystupu 40 dB
        db CHANNEL_1_OPERATOR_1 + OPL_ATTACK_DECAY,    0x31  ; modulator: pomaly nastup zvuku + pomale doznivani
        db CHANNEL_1_OPERATOR_1 + OPL_SUSTAIN_RELEASE, 0x71  ; urovne sustain a release pro modulator
        db CHANNEL_1_OPERATOR_1 + OPL_WAVE_SELECT,     0x00  ; standardni sinus
 
        db CHANNEL_1_OPERATOR_2 + OPL_AMP_VIBRATO_EG,  0x01  ; nastaveni nosne: nasobeni frekvence jednickou
        db CHANNEL_1_OPERATOR_2 + OPL_LEVEL,           0x0f  ; nastaveni urovne vystupu nosne na 47 dB
        db CHANNEL_1_OPERATOR_2 + OPL_ATTACK_DECAY,    0xa4  ; nosna: rychly nastup + pomale doznivani
        db CHANNEL_1_OPERATOR_2 + OPL_SUSTAIN_RELEASE, 0x71  ; urovne sustain a release pro nosnou
        db CHANNEL_1_OPERATOR_2 + OPL_WAVE_SELECT,     0x00  ; standardni sinus
 
        db CHANNEL_1_OPERATOR_3 + OPL_AMP_VIBRATO_EG,  0x01  ; nastaveni nosne: nasobeni frekvence jednickou
        db CHANNEL_1_OPERATOR_3 + OPL_LEVEL,           0x0f  ; nastaveni urovne vystupu nosne na 47 dB
        db CHANNEL_1_OPERATOR_3 + OPL_ATTACK_DECAY,    0xa4  ; nosna: rychly nastup + pomale doznivani
        db CHANNEL_1_OPERATOR_3 + OPL_SUSTAIN_RELEASE, 0x71  ; urovne sustain a release pro nosnou
        db CHANNEL_1_OPERATOR_3 + OPL_WAVE_SELECT,     0x00  ; standardni sinus
 
        db CHANNEL_1_OPERATOR_4 + OPL_AMP_VIBRATO_EG,  0x01  ; nastaveni nosne: nasobeni frekvence jednickou
        db CHANNEL_1_OPERATOR_4 + OPL_LEVEL,           0x00  ; nastaveni urovne vystupu nosne na 47 dB
        db CHANNEL_1_OPERATOR_4 + OPL_ATTACK_DECAY,    0x44  ; nosna: rychly nastup + pomale doznivani
        db CHANNEL_1_OPERATOR_4 + OPL_SUSTAIN_RELEASE, 0x77  ; urovne sustain a release pro nosnou
        db CHANNEL_1_OPERATOR_4 + OPL_WAVE_SELECT,     0x00  ; standardni sinus
 
        db CHANNEL_1 + OPL_FREQUENCY_LOW,              0x41  ; frekvence zvuku (komorni A = 440 Hz)
        db CHANNEL_1 + OPL_KEY_ON,                     0x12  ; zapnuti/povoleni zvuku + nastaveni oktavy a vyssich bitu frekvence
 
        db CHANNEL_1 + OPL_FEEDBACK,                   0b00110000  ; volba AM-FM
        db CHANNEL_1 + OPL_FEEDBACK + 3,               0b00110000  ; volba AM-FM
        db 0, 0                                              ; zarazka
 
 
perform_write_to_opl_register:
        ; zapis do vybraneho registru OPL2 nebo OPL3
        ; AL - registr
        ; AH - hodnota
        mov dx, OPL_ADDRESS   ; vyber registru pro modifikaci
        out dx, al
 
        mov al, ah            ; zapis hodnoty do vybraneho registru
        mov dx, OPL_DATA
        out dx, al
 
        ret
 
 
perform_write_to_opl_high_register:
        ; zapis do vybraneho "vyssiho" registru OPL3
        ; AL - registr
        ; AH - hodnota
        mov dx, OPL_HIGH_ADDRESS   ; vyber registru pro modifikaci
        out dx, al
 
        mov al, ah                 ; zapis hodnoty do vybraneho registru
        mov dx, OPL_HIGH_DATA
        out dx, al
 
        ret

17. Změna parametrů obálky v režimu se čtyřmi operátory

Rozdíl mezi AM a FM syntézou se ve skutečnosti projeví ve chvíli, kdy ještě více pozměníme obálky (ADSR) jednotlivých operátorů, které společně tvoří zvuk v prvním zvukovém kanálu. Poupravme tedy obálky takovým způsobem, aby měly velmi dlouhý dozvuk. Poté je již možné (a to opět klávesami 1–4) určovat způsob zapojení operátorů i zvolenou AM/FM syntézu (tedy všechny čtyři podporované kombinace neboli „algoritmy“):

; Prehrani tonu s vyuzitim 4 operatoru na kartach s cipem OPL3.
; Prepnuti do rezimu OPL3.
; Pojmenovani registru OPL3.
; Nastaveni pomaleho doznivani u vsech ctyr obalek.
; Ovladani KEY ON mezernikem
; Ukonceni aplikace stiskem ESC
;
;
; Tento demonstracni priklad je pouzity v serialu o programovani
; grafickych dem a her na PC v DOSu:
; https://www.root.cz/serialy/vyvoj-her-a-grafickych-dem-pro-platformu-pc/
;
;
; preklad pomoci:
;     nasm -f bin -o sounds_opl3_4operators_2.com sounds_opl3_4operators_2.asm
;
; nebo pouze:
;     nasm -o sounds_opl3_4operators_2.com sounds_opl3_4operators_2.asm

;-----------------------------------------------------------------------------

BITS 16         ; 16bitovy vystup pro DOS
CPU 8086        ; specifikace pouziteho instrukcniho souboru


;-----------------------------------------------------------------------------

; registry karet s cipem OPL3
OPL_ADDRESS           equ 0x220
OPL_DATA              equ 0x221
OPL_HIGH_ADDRESS      equ 0x222
OPL_HIGH_DATA         equ 0x223

; ridici registry OPL2
OPL_TEST_LSI             equ 0x01
OPL_TIMER_1              equ 0x02
OPL_TIMER_2              equ 0x03
OPL_TIMER_CTRL           equ 0x04
OPL_KBSPLIT              equ 0x08
OPL_AMP_VIBRATO_EG       equ 0x20
OPL_LEVEL                equ 0x40
OPL_ATTACK_DECAY         equ 0x60
OPL_SUSTAIN_RELEASE      equ 0x80
OPL_FREQUENCY_LOW        equ 0xa0
OPL_KEY_ON               equ 0xb0
OPL_AM_VIBRATO_RHYTHM    equ 0xbd
OPL_FEEDBACK             equ 0xc0
OPL_WAVE_SELECT          equ 0xe0
OPL_FOUR_OPERATOR_ENABLE equ 0x04 ; vyssi port!!!
OPL3_MODE_ENABLE         equ 0x05 ; vyssi port!!!

; indexy kanalu
CHANNEL_1 equ 0
CHANNEL_2 equ 1
CHANNEL_3 equ 2
CHANNEL_4 equ 3
CHANNEL_5 equ 4
CHANNEL_6 equ 5
CHANNEL_7 equ 6
CHANNEL_8 equ 7
CHANNEL_9 equ 8

; offsety pro jednotlive operatory v rezimu dvou operatoru
; --------------------------------------------------
;  Channel        1   2   3   4   5   6   7   8   9
;  Operator 1    00  01  02  08  09  0A  10  11  12
;  Operator 2    03  04  05  0B  0C  0D  13  14  15
; --------------------------------------------------
;  Channel        1   2   3   4   5   6   7   8   9

; offsety pro jednotlive operatory v rezimu ctyr operatoru
; --------------------------------------------------
;  Channel        1   2   3  10  11  12
;  Operator 1    00  01  02  12  13  14
;  Operator 2    03  04  05  15  16  17
;  Operator 3    08  09  0a  18  19  1a
;  Operator 4    0b  0c  0d  1b  1c  1d
; --------------------------------------------------
;  Channel        1   2   3  10  11  12
CHANNEL_1_OPERATOR_1 equ 0x00
CHANNEL_1_OPERATOR_2 equ 0x03
CHANNEL_1_OPERATOR_3 equ 0x08
CHANNEL_1_OPERATOR_4 equ 0x0b
CHANNEL_2_OPERATOR_1 equ 0x01
CHANNEL_2_OPERATOR_2 equ 0x04
CHANNEL_3_OPERATOR_1 equ 0x02
CHANNEL_3_OPERATOR_2 equ 0x05
CHANNEL_4_OPERATOR_1 equ 0x08
CHANNEL_4_OPERATOR_2 equ 0x0b
CHANNEL_5_OPERATOR_1 equ 0x09
CHANNEL_5_OPERATOR_2 equ 0x0c
CHANNEL_6_OPERATOR_1 equ 0x0a
CHANNEL_6_OPERATOR_2 equ 0x0d
CHANNEL_7_OPERATOR_1 equ 0x10
CHANNEL_7_OPERATOR_2 equ 0x13
CHANNEL_8_OPERATOR_1 equ 0x11
CHANNEL_8_OPERATOR_2 equ 0x14
CHANNEL_9_OPERATOR_1 equ 0x12
CHANNEL_9_OPERATOR_2 equ 0x15

; registry PPI
PPI_PORT_A equ 0x60
PPI_PORT_B equ 0x61

; kody klaves
KEY_ESC     equ 0x01
KEY_SPACE   equ 0x39
KEY_RELEASE equ 0x80
KEY_1       equ 0x02
KEY_2       equ 0x03
KEY_3       equ 0x04
KEY_4       equ 0x05


;-----------------------------------------------------------------------------

; ukonceni procesu a navrat do DOSu
%macro exit 0
        ret
%endmacro

; makro pro zapis do registru OPL2 nebo OPL3
%macro write_opl_register 2
        mov     al, %1
        mov     ah, %2
        call    perform_write_to_opl_register
%endmacro

; makro pro zapis do "vyssiho" registru OPL3
%macro write_opl_high_register 2
        mov     al, %1
        mov     ah, %2
        call    perform_write_to_opl_high_register
%endmacro

;-----------------------------------------------------------------------------
org  0x100        ; zacatek kodu pro programy typu COM (vzdy se zacina na 256)

start:
        push cs
        pop  ds                          ; DS==CS

        write_opl_high_register OPL3_MODE_ENABLE, 1
        write_opl_high_register OPL_FOUR_OPERATOR_ENABLE, 0b00000001

        mov  si, tone1                   ; zacatek tabulky
        call write_table_to_opl3         ; zapis obsahu tabulky do OPL3

        in  al, PPI_PORT_B               ; port B s rizenim zarizeni
        or  al, 0b1000000                ; nastaveni bitu cislo 7 na jednicku
        out PPI_PORT_B, al               ; zapis zpet na port B

.opak:
        in  al, PPI_PORT_A               ; cteni stisknute klavesy
        cmp al, KEY_SPACE                ; test na stisk mezerniku
        jne .next_test_1                 ; neni stisknut -> preskok
        write_opl_register CHANNEL_1 + OPL_KEY_ON, 0x32    ; povoleni KEY ON bitu
        jmp .opak
.next_test_1:
        cmp al, KEY_SPACE + KEY_RELEASE  ; test na pusteni mezerniku
        jne .next_test_2                 ; neni pusten -> dalsi test
        write_opl_register CHANNEL_1 + OPL_KEY_ON, 0x12    ; zakaz KEY ON bitu
        jmp .opak
.next_test_2:
        cmp al, KEY_1
        jne .next_test_3
        write_opl_register CHANNEL_1 + OPL_FEEDBACK, 0b00110000 ; FM
        jmp .opak
.next_test_3:
        cmp al, KEY_2
        jne .next_test_4
        write_opl_register CHANNEL_1 + OPL_FEEDBACK, 0b00110001 ; AM
        jmp .opak
.next_test_4:
        cmp al, KEY_3
        jne .next_test_5
        write_opl_register CHANNEL_1 + OPL_FEEDBACK + 3, 0b00110000 ; FM
        jmp .opak
.next_test_5:
        cmp al, KEY_4
        jne .next_test_6
        write_opl_register CHANNEL_1 + OPL_FEEDBACK + 3, 0b00110001 ; AM
        jmp .opak
.next_test_6:
        cmp al, KEY_ESC                  ; test stisknute klavesy ESC
        jne .opak                        ; neni stisknuta? -> zkusme znovu

        exit


write_table_to_opl3:
        lodsb                            ; nacist bajt z tabulky (cislo registru)
        or  al, al                       ; test na nulu
        jnz .write_register
        ret                              ; dosahli jsme konce tabulky
.write_register:
        mov ah, al
        lodsb                            ; nacist dalsi bajt z tabulky (hodnota registru)
        xchg al, ah                      ; podprogram vyzaduje opacne poradi AL, AH
        call perform_write_to_opl_register
        jmp  write_table_to_opl3         ; muzeme prejit na dalsi registr


tone1:  ; tabulka s tonem pro prvni kanal
        db CHANNEL_1_OPERATOR_1 + OPL_AMP_VIBRATO_EG,  0x01  ; nastaveni modulatoru: nasobeni frekvence jednickou
        db CHANNEL_1_OPERATOR_1 + OPL_LEVEL,           0x00  ; uroven vystupu 40 dB
        db CHANNEL_1_OPERATOR_1 + OPL_ATTACK_DECAY,    0x31  ; modulator: pomaly nastup zvuku + pomale doznivani
        db CHANNEL_1_OPERATOR_1 + OPL_SUSTAIN_RELEASE, 0x71  ; urovne sustain a release pro modulator
        db CHANNEL_1_OPERATOR_1 + OPL_WAVE_SELECT,     0x00  ; standardni sinus

        db CHANNEL_1_OPERATOR_2 + OPL_AMP_VIBRATO_EG,  0x01  ; nastaveni nosne: nasobeni frekvence jednickou
        db CHANNEL_1_OPERATOR_2 + OPL_LEVEL,           0x0f  ; nastaveni urovne vystupu nosne na 47 dB
        db CHANNEL_1_OPERATOR_2 + OPL_ATTACK_DECAY,    0xa1  ; nosna: rychly nastup + pomale doznivani
        db CHANNEL_1_OPERATOR_2 + OPL_SUSTAIN_RELEASE, 0x71  ; urovne sustain a release pro nosnou
        db CHANNEL_1_OPERATOR_2 + OPL_WAVE_SELECT,     0x00  ; standardni sinus

        db CHANNEL_1_OPERATOR_3 + OPL_AMP_VIBRATO_EG,  0x01  ; nastaveni nosne: nasobeni frekvence jednickou
        db CHANNEL_1_OPERATOR_3 + OPL_LEVEL,           0x0f  ; nastaveni urovne vystupu nosne na 47 dB
        db CHANNEL_1_OPERATOR_3 + OPL_ATTACK_DECAY,    0xa1  ; nosna: rychly nastup + pomale doznivani
        db CHANNEL_1_OPERATOR_3 + OPL_SUSTAIN_RELEASE, 0x71  ; urovne sustain a release pro nosnou
        db CHANNEL_1_OPERATOR_3 + OPL_WAVE_SELECT,     0x00  ; standardni sinus

        db CHANNEL_1_OPERATOR_4 + OPL_AMP_VIBRATO_EG,  0x01  ; nastaveni nosne: nasobeni frekvence jednickou
        db CHANNEL_1_OPERATOR_4 + OPL_LEVEL,           0x00  ; nastaveni urovne vystupu nosne na 47 dB
        db CHANNEL_1_OPERATOR_4 + OPL_ATTACK_DECAY,    0x41  ; nosna: rychly nastup + pomale doznivani
        db CHANNEL_1_OPERATOR_4 + OPL_SUSTAIN_RELEASE, 0x77  ; urovne sustain a release pro nosnou
        db CHANNEL_1_OPERATOR_4 + OPL_WAVE_SELECT,     0x00  ; standardni sinus

        db CHANNEL_1 + OPL_FREQUENCY_LOW,              0x41  ; frekvence zvuku (komorni A = 440 Hz)
        db CHANNEL_1 + OPL_KEY_ON,                     0x12  ; zapnuti/povoleni zvuku + nastaveni oktavy a vyssich bitu frekvence

        db CHANNEL_1 + OPL_FEEDBACK,                   0b00110001  ; volba AM-FM
        db CHANNEL_1 + OPL_FEEDBACK + 3,               0b00110001  ; volba AM-FM
        db 0, 0                                              ; zarazka


perform_write_to_opl_register:
        ; zapis do vybraneho registru OPL2 nebo OPL3
        ; AL - registr
        ; AH - hodnota
        mov dx, OPL_ADDRESS   ; vyber registru pro modifikaci
        out dx, al

        mov al, ah            ; zapis hodnoty do vybraneho registru
        mov dx, OPL_DATA
        out dx, al

        ret


perform_write_to_opl_high_register:
        ; zapis do vybraneho "vyssiho" registru OPL3
        ; AL - registr
        ; AH - hodnota
        mov dx, OPL_HIGH_ADDRESS   ; vyber registru pro modifikaci
        out dx, al

        mov al, ah                 ; zapis hodnoty do vybraneho registru
        mov dx, OPL_HIGH_DATA
        out dx, al

        ret

18. Příloha: skript pro vykreslení sedmi signálů generovaných oscilátory čipu OPL3

Skript, kterým byly vykresleny obrázky 1 a 7 ve druhé a třetí kapitole, vypadá následovně:

import numpy as np
import matplotlib.pyplot as plt
from scipy import signal
 
 
def plot(x, y, filename, title):
    # nastaveni os
    plt.xticks(ticks=np.floor(np.linspace(0, 511, 9)))
    plt.yticks(ticks=np.linspace(-1.5, 1.5, 7))
    plt.xlim([0, 511])
    plt.ylim([-1.5, 1.5])
 
    # vykresleni
    plt.plot(x, y)
 
    # mrizka a dalsi parametry grafu
    plt.grid()
    plt.title(title)
 
    # ulozeni na disk
    plt.savefig(filename)
 
    # zobrazeni
    plt.show()
 
    plt.clf()
 
 
# prubeh vlny
x = np.linspace(0, 511, 200)
y = np.sin(x * 2 * np.pi / 256.0)
plot(x, y, "waveform_0.png", "Tvar vlny #0: sinus")
 
# vynulovat zaporne hodnoty
y[y < 0] = 0
plot(x, y, "waveform_1.png", "Tvar vlny #1: polovicni sinus")
 
# absolutni hodnoty
y = np.abs(np.sin(x * 2 * np.pi / 256.0))
plot(x, y, "waveform_2.png", "Tvar vlny #2: absolutni hodnoty sinu")
 
# vynulovat liché periody
y = np.abs(np.sin(x * 2 * np.pi / 256.0))
y2 = signal.square(4 * np.pi / 256.0 * x)
y3 = y * y2
y3[y3 < 0] = 0
plot(x, y3, "waveform_3.png", "Tvar vlny #3: pulsní varianta")
 
y = np.sin(x * 4 * np.pi / 256.0)
y2 = signal.square(2 * np.pi / 256.0 * x)
y2[y2 < 0] = 0
y3 = y * y2
plot(x, y3, "waveform_4.png", "Tvar vlny #4: jen sudé vlny")
 
y = np.abs(np.sin(x * 4 * np.pi / 256.0))
y2 = signal.square(2 * np.pi / 256.0 * x)
y2[y2 < 0] = 0
y3 = y * y2
plot(x, y3, "waveform_5.png", "Tvar vlny #5: jen sudé vlny, abs sin")
 
# klasicky obdelnik
y = signal.square(2 * np.pi / 256.0 * x)
plot(x, y, "waveform_6.png", "Tvar vlny #6: obdélník")

19. Repositář s demonstračními příklady

Demonstrační příklady napsané v assembleru, které jsou určené pro překlad s využitím assembleru NASM, byly uloženy do Git repositáře, který je dostupný na adrese https://github.com/tisnik/8bit-fame. Jednotlivé demonstrační příklady si můžete v případě potřeby stáhnout i jednotlivě bez nutnosti klonovat celý (dnes již poměrně rozsáhlý) repositář:

20. Odkazy na Internetu

1. The Intel 8088 Architecture and Instruction Set
   https://people.ece.ubc.ca/~ed­c/464/lectures/lec4.pdf
2. x86 Opcode Structure and Instruction Overview
   https://pnx.tf/files/x86_op­code_structure_and_instruc­tion_overview.pdf
3. x86 instruction listings (Wikipedia)
   https://en.wikipedia.org/wi­ki/X86_instruction_listin­gs
4. x86 assembly language (Wikipedia)
   https://en.wikipedia.org/wi­ki/X86_assembly_language
5. Intel Assembler (Cheat sheet)
   http://www.jegerlehner.ch/in­tel/IntelCodeTable.pdf
6. 25 Microchips That Shook the World
   https://spectrum.ieee.org/tech-history/silicon-revolution/25-microchips-that-shook-the-world
7. Chip Hall of Fame: MOS Technology 6502 Microprocessor
   https://spectrum.ieee.org/tech-history/silicon-revolution/chip-hall-of-fame-mos-technology-6502-microprocessor
8. Chip Hall of Fame: Intel 8088 Microprocessor
   https://spectrum.ieee.org/tech-history/silicon-revolution/chip-hall-of-fame-intel-8088-microprocessor
9. Jak se zrodil procesor?
   https://www.root.cz/clanky/jak-se-zrodil-procesor/
10. Apple II History Home
    http://apple2history.org/
11. The 8086/8088 Primer
    https://www.stevemorse.or­g/8086/index.html
12. flat assembler: Assembly language resources
    https://flatassembler.net/
13. FASM na Wikipedii
    https://en.wikipedia.org/wiki/FASM
14. Fresh IDE FASM inside
    https://fresh.flatassembler.net/
15. MS-DOS Version 4.0 Programmer's Reference
    https://www.pcjs.org/docu­ments/books/mspl13/msdos/dos­ref40/
16. INT 21 – DOS Function Dispatcher (DOS)
    https://www.stanislavs.or­g/helppc/int₂₁.html
17. DOS API (Wikipedia)
    https://en.wikipedia.org/wiki/DOS_API
18. Bit banging
    https://en.wikipedia.org/wi­ki/Bit_banging
19. IBM Basic assembly language and successors (Wikipedia)
    https://en.wikipedia.org/wi­ki/IBM_Basic_assembly_lan­guage_and_successors
20. X86 Assembly/Bootloaders
    https://en.wikibooks.org/wi­ki/X86_Assembly/Bootloaders
21. Počátky grafiky na PC: grafické karty CGA a Hercules
    https://www.root.cz/clanky/pocatky-grafiky-na-pc-graficke-karty-cga-a-hercules/
22. Co mají společného Commodore PET/4000, BBC Micro, Amstrad CPC i grafické karty MDA, CGA a Hercules?
    https://www.root.cz/clanky/co-maji-spolecneho-commodore-pet-4000-bbc-micro-amstrad-cpc-i-graficke-karty-mda-cga-a-hercules/
23. Karta EGA: první použitelná barevná grafika na PC
    https://www.root.cz/clanky/karta-ega-prvni-pouzitelna-barevna-grafika-na-pc/
24. RGB Classic Games
    https://www.classicdosgames.com/
25. Turbo Assembler (Wikipedia)
    https://en.wikipedia.org/wi­ki/Turbo_Assembler
26. Microsoft Macro Assembler
    https://en.wikipedia.org/wi­ki/Microsoft_Macro_Assembler
27. IBM Personal Computer (Wikipedia)
    https://en.wikipedia.org/wi­ki/IBM_Personal_Computer
28. Intel 8251
    https://en.wikipedia.org/wi­ki/Intel_8251
29. Intel 8253
    https://en.wikipedia.org/wi­ki/Intel_8253
30. Intel 8255
    https://en.wikipedia.org/wi­ki/Intel_8255
31. Intel 8257
    https://en.wikipedia.org/wi­ki/Intel_8257
32. Intel 8259
    https://en.wikipedia.org/wi­ki/Intel_8259
33. Support/peripheral/other chips – 6800 family
    http://www.cpu-world.com/Support/6800.html
34. Motorola 6845
    http://en.wikipedia.org/wi­ki/Motorola_6845
35. The 6845 Cathode Ray Tube Controller (CRTC)
    http://www.tinyvga.com/6845
36. CRTC operation
    http://www.6502.org/users/an­dre/hwinfo/crtc/crtc.html
37. 6845 – Motorola CRT Controller
    https://stanislavs.org/hel­ppc/6845.html
38. The 6845 Cathode Ray Tube Controller (CRTC)
    http://www.tinyvga.com/6845
39. Motorola 6845 and bitwise graphics
    https://retrocomputing.stac­kexchange.com/questions/10996/mo­torola-6845-and-bitwise-graphics
40. IBM Monochrome Display Adapter
    http://en.wikipedia.org/wi­ki/Monochrome_Display_Adap­ter
41. Color Graphics Adapter
    http://en.wikipedia.org/wi­ki/Color_Graphics_Adapter
42. Color Graphics Adapter and the Brown color in IBM 5153 Color Display
    https://www.aceinnova.com/en/e­lectronics/cga-and-the-brown-color-in-ibm-5153-color-display/
43. The Modern Retrocomputer: An Arduino Driven 6845 CRT Controller
    https://hackaday.com/2017/05/14/the-modern-retrocomputer-an-arduino-driven-6845-crt-controller/
44. flat assembler: Assembly language resources
    https://flatassembler.net/
45. FASM na Wikipedii
    https://en.wikipedia.org/wiki/FASM
46. Fresh IDE FASM inside
    https://fresh.flatassembler.net/
47. MS-DOS Version 4.0 Programmer's Reference
    https://www.pcjs.org/docu­ments/books/mspl13/msdos/dos­ref40/
48. INT 21 – DOS Function Dispatcher (DOS)
    https://www.stanislavs.or­g/helppc/int₂₁.html
49. DOS API (Wikipedia)
    https://en.wikipedia.org/wiki/DOS_API
50. IBM Basic assembly language and successors (Wikipedia)
    https://en.wikipedia.org/wi­ki/IBM_Basic_assembly_lan­guage_and_successors
51. X86 Assembly/Arithmetic
    https://en.wikibooks.org/wi­ki/X86_Assembly/Arithmetic
52. Art of Assembly – Arithmetic Instructions
    http://oopweb.com/Assembly/Do­cuments/ArtOfAssembly/Volu­me/Chapter₆/CH06–2.html
53. ASM Flags
    http://www.cavestory.org/gu­ides/csasm/guide/asm_flag­s.html
54. Status Register
    https://en.wikipedia.org/wi­ki/Status_register
55. Linux assemblers: A comparison of GAS and NASM
    http://www.ibm.com/develo­perworks/library/l-gas-nasm/index.html
56. Programovani v assembleru na OS Linux
    http://www.cs.vsb.cz/gryga­rek/asm/asmlinux.html
57. Is it worthwhile to learn x86 assembly language today?
    https://www.quora.com/Is-it-worthwhile-to-learn-x86-assembly-language-today?share=1
58. Why Learn Assembly Language?
    http://www.codeproject.com/Ar­ticles/89460/Why-Learn-Assembly-Language
59. Is Assembly still relevant?
    http://programmers.stackex­change.com/questions/95836/is-assembly-still-relevant
60. Why Learning Assembly Language Is Still a Good Idea
    http://www.onlamp.com/pub/a/on­lamp/2004/05/06/writegreat­code.html
61. Assembly language today
    http://beust.com/weblog/2004/06/23/as­sembly-language-today/
62. Assembler: Význam assembleru dnes
    http://www.builder.cz/rubri­ky/assembler/vyznam-assembleru-dnes-155960cz
63. Programming from the Ground Up Book – Summary
    http://savannah.nongnu.or­g/projects/pgubook/
64. DOSBox
    https://www.dosbox.com/
65. The C Programming Language
    https://en.wikipedia.org/wi­ki/The_C_Programming_Langu­age
66. Hercules Graphics Card (HCG)
    https://en.wikipedia.org/wi­ki/Hercules_Graphics_Card
67. Complete 8086 instruction set
    https://content.ctcd.edu/cou­rses/cosc2325/m22/docs/emu8086in­s.pdf
68. Complete 8086 instruction set
    https://yassinebridi.github.io/asm-docs/8086_instruction_set.html
69. 8088 MPH by Hornet + CRTC + DESiRE (final version)
    https://www.youtube.com/wat­ch?v=hNRO7lno_DM
70. Area 5150 by CRTC & Hornet (Party Version) / IBM PC+CGA Demo, Hardware Capture
    https://www.youtube.com/wat­ch?v=fWDxdoRTZPc
71. 80×86 Integer Instruction Set Timings (8088 – Pentium)
    http://aturing.umcs.maine­.edu/~meadow/courses/cos335/80×86-Integer-Instruction-Set-Clocks.pdf
72. Colour Graphics Adapter: Notes
    https://www.seasip.info/Vin­tagePC/cga.html
73. Restoring A Vintage CGA Card With Homebrew HASL
    https://hackaday.com/2024/06/12/res­toring-a-vintage-cga-card-with-homebrew-hasl/
74. Demoing An 8088
    https://hackaday.com/2015/04/10/de­moing-an-8088/
75. Video Memory Layouts
    http://www.techhelpmanual.com/89-video_memory_layouts.html
76. Screen Attributes
    http://www.techhelpmanual.com/87-screen_attributes.html
77. IBM PC Family – BIOS Video Modes
    https://www.minuszerodegre­es.net/video/bios_video_mo­des.htm
78. EGA Functions
    https://cosmodoc.org/topics/ega-functions/#the-hierarchy-of-the-ega
79. Why the EGA can only use 16 of its 64 colours in 200-line modes
    https://www.reenigne.org/blog/why-the-ega-can-only-use-16-of-its-64-colours-in-200-line-modes/
80. How 16 colors saved PC gaming – the story of EGA graphics
    https://www.custompc.com/retro-tech/ega-graphics
81. List of 16-bit computer color palettes
    https://en.wikipedia.org/wi­ki/List_of₁₆-bit_computer_color_palettes
82. Why were those colors chosen to be the default palette for 256-color VGA?
    https://retrocomputing.stac­kexchange.com/questions/27994/why-were-those-colors-chosen-to-be-the-default-palette-for-256-color-vga
83. VGA Color Palettes
    https://www.fountainware.com/EX­PL/vga_color_palettes.htm
84. Hardware Level VGA and SVGA Video Programming Information Page
    http://www.osdever.net/Fre­eVGA/vga/vga.htm
85. Hardware Level VGA and SVGA Video Programming Information Page – sequencer
    http://www.osdever.net/Fre­eVGA/vga/seqreg.htm
86. VGA Basics
    http://www.brackeen.com/vga/ba­sics.html
87. Introduction to VGA Mode ‚X‘
    https://web.archive.org/web/20160414072210/htt­p://fly.srk.fer.hr/GDM/ar­ticles/vgamodex/vgamx1.html
88. VGA Mode-X
    https://web.archive.org/web/20070123192523/htt­p://www.gamedev.net/referen­ce/articles/article356.asp
89. Mode-X: 256-Color VGA Magic
    https://downloads.gamedev­.net/pdf/gpbb/gpbb47.pdf
90. Instruction Format in 8086 Microprocessor
    https://www.includehelp.com/embedded-system/instruction-format-in-8086-microprocessor.aspx
91. How to use „AND,“ „OR,“ and „XOR“ modes for VGA Drawing
    https://retrocomputing.stac­kexchange.com/questions/21936/how-to-use-and-or-and-xor-modes-for-vga-drawing
92. VGA Hardware
    https://wiki.osdev.org/VGA_Hardware
93. Programmer's Guide to Yamaha YMF 262/OPL3 FM Music Synthesizer
    https://moddingwiki.shika­di.net/wiki/OPL_chip
94. Does anybody understand how OPL2 percussion mode works?
    https://forum.vcfed.org/in­dex.php?threads/does-anybody-understand-how-opl2-percussion-mode-works.60925/
95. Yamaha YMF262 OPL3 music – MoonDriver for OPL3 DEMO [Oscilloscope View]
    https://www.youtube.com/watch?v=a7I-QmrkAak
96. Yamaha OPL vs OPL2 vs OPL3 comparison
    https://www.youtube.com/wat­ch?v=5knetge5Gs0
97. OPL3 Music Crockett's Theme
    https://www.youtube.com/wat­ch?v=HXS008pkgSQ
98. Bad Apple (Adlib Tracker – OPL3)
    https://www.youtube.com/wat­ch?v=2lEPH6Y3Luo
99. FM Synthesis Chips, Codecs and DACs
    https://www.dosdays.co.uk/to­pics/fm_synthesizers.php
100. The Zen Challenge – YMF262 OPL3 Original (For an upcoming game)
     https://www.youtube.com/wat­ch?v=6JlFIFz1CFY
101. [adlib tracker II techno music – opl3] orbit around alpha andromedae I
     https://www.youtube.com/wat­ch?v=YqxJCu_WFuA
102. [adlib tracker 2 music – opl3 techno] hybridisation process on procyon-ii
     https://www.youtube.com/wat­ch?v=daSV5mN0sJ4
103. Hyper Duel – Black Rain (YMF262 OPL3 Cover)
     https://www.youtube.com/wat­ch?v=pu_mzRRq8Ho
104. IBM 5155–5160 Technical Reference
     https://www.minuszerodegre­es.net/manuals/IBM/IBM_5155_5160_Techni­cal_Reference_6280089_MAR86­.pdf
105. a ymf262/opl3+pc speaker thing i made
     https://www.youtube.com/watch?v=E-Mx0lEmnZ0
106. [OPL3] Like a Thunder
     https://www.youtube.com/wat­ch?v=MHf06AGr8SU
107. (PC SPEAKER) bad apple
     https://www.youtube.com/wat­ch?v=LezmKIIHyUg
108. Powering devices from PC parallel port
     http://www.epanorama.net/cir­cuits/lptpower.html
109. Magic Mushroom (demo pro PC s DOSem)
     http://www.crossfire-designs.de/download/articles/sou­ndcards//mushroom.rar
110. Píseň Magic Mushroom – originál
     http://www.crossfire-designs.de/download/articles/sou­ndcards/speaker_mushroom_con­verted.mp3
111. Píseň Magic Mushroom – hráno na PC Speakeru
     http://www.crossfire-designs.de/download/articles/sou­ndcards/speaker_mushroom_spe­aker.mp3
112. Pulse Width Modulation (PWM) Simulation Example
     http://decibel.ni.com/content/docs/DOC-4599
113. Resistor/Pulse Width Modulation DAC
     http://www.k9spud.com/trax­mod/pwmdac.php
114. Class D Amplifier
     http://en.wikipedia.org/wi­ki/Electronic_amplifier#Clas­s_D
115. Covox Speech Thing / Disney Sound Source (1986)
     http://www.crossfire-designs.de/index.php?lang=en&what=ar­ticles&name=showarticle.htm&ar­ticle=soundcards/&page=5
116. Covox Digital-Analog Converter (Rusky, obsahuje schémata)
     http://phantom.sannata.ru/kon­kurs/netskater002.shtml
117. PC-GPE on the Web
     http://bespin.org/~qz/pc-gpe/
118. Keyboard Synthesizer
     http://www.solarnavigator­.net/music/instruments/ke­yboards.htm
119. FMS – Fully Modular Synthesizer
     http://fmsynth.sourceforge.net/
120. Javasynth
     http://javasynth.sourceforge.net/
121. Software Sound Synthesis & Music Composition Packages
     http://www.linux-sound.org/swss.html
122. Mx44.1 Download Page (software synthesizer for linux)
     http://hem.passagen.se/ja_linux/
123. Software synthesizer
     http://en.wikipedia.org/wi­ki/Software_synthesizer
124. Frequency modulation synthesis
     http://en.wikipedia.org/wi­ki/Frequency_modulation_syn­thesis
125. Yamaha DX7
     http://en.wikipedia.org/wi­ki/Yamaha_DX7
126. Wave of the Future
     http://www.wired.com/wired/ar­chive/2.03/waveguides_pr.html
127. Analog synthesizer
     http://en.wikipedia.org/wi­ki/Analog_synthesizer
128. Minimoog
     http://en.wikipedia.org/wiki/Minimoog
129. Moog synthesizer
     http://en.wikipedia.org/wi­ki/Moog_synthesizer
130. Tutorial for Frequency Modulation Synthesis
     http://www.sfu.ca/~truax/fmtut.html
131. An Introduction To FM
     http://ccrma.stanford.edu/sof­tware/snd/snd/fm.html
132. John Chowning
     http://en.wikipedia.org/wi­ki/John_Chowning
133. I'm Impressed, Adlib Music is AMAZING!
     https://www.youtube.com/wat­ch?v=PJNjQYp1ras
134. Milinda- Diode Milliampere ( OPL3 )
     https://www.youtube.com/wat­ch?v=oNhazT5HG0E
135. Dune 2 – Roland MT-32 Soundtrack
     https://www.youtube.com/wat­ch?v=kQADZeB-z8M